convai-sdk-cpp/WORKSPACE at master · Conv-AI/convai-sdk-cpp · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
##### Protobuf Rules for Bazel
##### See https://github.com/bazelbuild/rules_proto
load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
load("@bazel_tools//tools/build_defs/repo:git.bzl", "new_git_repository")

http_archive(
    name = "rules_proto",
    sha256 = "80d3a4ec17354cccc898bfe32118edd934f851b03029d63ef3fc7c8663a7415c",
    strip_prefix = "rules_proto-5.3.0-21.5",
    urls = [
        "https://github.com/bazelbuild/rules_proto/archive/refs/tags/5.3.0-21.5.tar.gz",
    ],
)
load("@rules_proto//proto:repositories.bzl", "rules_proto_dependencies", "rules_proto_toolchains")
rules_proto_dependencies()
rules_proto_toolchains()

##### gRPC Rules for Bazel
##### See https://github.com/grpc/grpc/blob/master/src/cpp/README.md#make
##### Release: https://github.com/grpc/grpc/commit/0e34ec3396726ba44a7aaf752eccac0e998beaa8
http_archive(
    name = "com_github_grpc_grpc",
    urls = [
        "https://github.com/grpc/grpc/archive/0e34ec3396726ba44a7aaf752eccac0e998beaa8.tar.gz",
    ],
    strip_prefix = "grpc-0e34ec3396726ba44a7aaf752eccac0e998beaa8",
)
load("@com_github_grpc_grpc//bazel:grpc_deps.bzl", "grpc_deps")
grpc_deps()
load("@com_github_grpc_grpc//bazel:grpc_extra_deps.bzl", "grpc_extra_deps")
grpc_extra_deps()

new_git_repository(
    name = "portaudio",
    build_file_content = """
load("@rules_cc//cc:defs.bzl", "cc_library")
package(default_visibility = ["//visibility:public"])
licenses(["reciprocal"])
exports_files(["LICENSE.txt"])
cc_library(
    name = "portaudio",
    srcs = glob([
        "src/common/*.c",
        "src/common/*.h",
        "include/*.h",
    ]) + select({
        "@platforms//os:linux": glob([
            "src/hostapi/alsa/*.c",
            "src/hostapi/alsa/*.h",
            "src/os/unix/*.c",
            "src/os/unix/*.h",
        ]),
        "@platforms//os:osx": glob([
            "src/hostapi/coreaudio/*.c",
            "src/hostapi/coreaudio/*.h",
            "src/os/unix/*.c",
            "src/os/unix/*.h",
        ]),
        "@platforms//os:windows": glob([
            "src/hostapi/wmme/*.c",
            "src/hostapi/wmme/*.h",
            "src/os/win/*.c",
            "src/os/win/*.h",
        ]),
        "//conditions:default": [],
    }),
    hdrs = ["include/portaudio.h"],
    copts = select({
        "@platforms//os:windows": ["/w"],
        "//conditions:default": ["-w"],
    }),
    defines = select({
        "@platforms//os:linux": ["PA_USE_ALSA=1"],
        "@platforms//os:osx": ["PA_USE_COREAUDIO=1"],
        "@platforms//os:windows": ["PA_USE_WMME=1"],
        "//conditions:default": [],
    }),
    includes = [
        "include",
        "src/common",
        "src/os/unix",
    ],
    linkopts = select({
        "@platforms//os:linux": [
            "-lasound",
            "-pthread",
        ],
        "@platforms//os:osx": [
            "-framework AudioUnit",
            "-framework CoreAudio",
            "-framework AudioToolbox",
            "-framework Carbon",
        ],
        "//conditions:default": [],
    }),
)
    """,
    commit = "147dd722548358763a8b649b3e4b41dfffbcfbb6",
    remote = "https://github.com/PortAudio/portaudio.git",
    shallow_since = "1617236250 -0700",
)