Particles/Particles.pro at master · JulioC/Particles · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
QT += core gui opengl

RENDERERS = \
  point \
  sphere \
  square \
  vbo

INITIALIZERS = \
  lifetime \
  speedoffset \
  color \
  speed \
  radius \
  direction \
  position

OPERATORS = \
  decay \
  acceleration \
  drag \
  fade

V3DGENERATORS = \
  cone \
  sphere \
  box \
  point \
  cylinder \
  list

COLORGENERATORS = \
  constant \
  range \
  list

HEADERS += \
  particle.h \
  vector3d.h \
  window.h \
  glwidget.h \
  emitter.h \
  renderer.h \
  operator.h \
  initializer.h \
  timer.h \
  color.h \
  camera.h \
  camerashader.h \
  random.h \
  v3dgenerator.h \
  colorgenerator.h \
  testbed.h \
  emitterspanel.h \
    emittercontroller.h

SOURCES += \
  particle.cpp \
  vector3d.cpp \
  main.cpp \
  window.cpp \
  glwidget.cpp \
  emitter.cpp \
  timer.cpp \
  color.cpp \
  camera.cpp \
  camerashader.cpp \
  random.cpp \
  testbed.cpp \
  emitterspanel.cpp \
    emittercontroller.cpp

RESOURCES += \
  resources.qrc

OTHER_FILES += \
  vshader.glsl \
  fshader.glsl \
  README.md \
  LICENSE

# Add  Renders, Initializers and Operators
for(name, RENDERERS) {
  HEADERS += renderers/rend_$${name}.h
  SOURCES += renderers/rend_$${name}.cpp
}
for(name, INITIALIZERS) {
  HEADERS += initializers/init_$${name}.h
  SOURCES += initializers/init_$${name}.cpp
}
for(name, OPERATORS) {
  HEADERS += operators/oper_$${name}.h
  SOURCES += operators/oper_$${name}.cpp
}
for(name, V3DGENERATORS) {
  HEADERS += v3dgenerators/v3dgen_$${name}.h
  SOURCES += v3dgenerators/v3dgen_$${name}.cpp
}
for(name, COLORGENERATORS) {
  HEADERS += colorgenerators/colorgen_$${name}.h
  SOURCES += colorgenerators/colorgen_$${name}.cpp
}

FORMS += \
  testbed.ui \
  emitterspanel.ui \
    emittercontroller.ui