meson: Add installcheck equivalent

Author: anarazel

.cirrus.yml

@@ -121,6 +121,17 @@ task:
       meson test $MTEST_ARGS --num-processes ${TEST_JOBS}
     EOF
 
+  # test runningcheck
+  test_running_script: |
+    su postgres <<-EOF
+      ulimit -c unlimited
+      export LD_LIBRARY_PATH="$(pwd)/tmp_install/usr/local/lib/:$LD_LIBRARY_PATH"
+      tmp_install/usr/local/bin/initdb
+      tmp_install/usr/local/bin/pg_ctl -c -o '-c fsync=off' -D runningcheck -l testrun/runningcheck.log start
+      meson test $MTEST_ARGS --num-processes ${TEST_JOBS} --setup running
+      tmp_install/usr/local/bin/pg_ctl -D runningcheck -l testrun/runningcheck.log stop
+    EOF
+
   on_failure:
     <<: *on_failure_meson
     cores_script: src/tools/ci/cores_backtrace.sh freebsd /tmp/cores

contrib/basic_archive/meson.build

@@ -25,5 +25,6 @@ tests += {
     'regress_args': [
       '--temp-config', files('basic_archive.conf'),
     ],
+    'runningcheck': false,
   },
 }

contrib/pg_freespacemap/meson.build

@@ -33,5 +33,8 @@ tests += {
     'regress_args': [
       '--temp-config', files('pg_freespacemap.conf')
     ],
+    # Disabled because these tests require "autovacuum=off", which
+    # typical runningcheck users do not have (e.g. buildfarm clients).
+    'runningcheck': false,
   },
 }

contrib/pg_stat_statements/meson.build

@@ -41,5 +41,9 @@ tests += {
       'pg_stat_statements',
     ],
     'regress_args': ['--temp-config', files('pg_stat_statements.conf')],
+    # Disabled because these tests require
+    # "shared_preload_libraries=pg_stat_statements", which typical
+    # runningcheck users do not have (e.g. buildfarm clients).
+    'runningcheck': false,
   },
 }

contrib/pg_walinspect/meson.build

@@ -28,6 +28,9 @@ tests += {
     'sql': [
       'pg_walinspect',
     ],
+    # Disabled because these tests require "wal_level=replica", which
+    # some runningcheck users do not have (e.g. buildfarm clients).
     'regress_args': ['--temp-config', files('walinspect.conf')],
+    'runningcheck': false,
   },
 }

contrib/test_decoding/meson.build

@@ -43,6 +43,9 @@ tests += {
     'regress_args': [
       '--temp-config', files('logical.conf'),
     ],
+    # Disabled because these tests require "wal_level=logical", which
+    # typical runningcheck users do not have (e.g. buildfarm clients).
+    'runningcheck': false,
   },
   'isolation': {
     'specs': [
@@ -60,6 +63,8 @@ tests += {
     'regress_args': [
       '--temp-config', files('logical.conf'),
     ],
+    # see above
+    'runningcheck': false,
   },
   'tap': {
     'tests': [

meson.build

@@ -2889,6 +2889,21 @@ endif
 # Test Generation
 ###############################################################
 
+# when using a meson version understanding exclude_suites, define a 'default'
+# test setup that excludes tests running against a pre-existing install and a
+# 'running' setup that conflicts with creation of the temporary installation
+# and tap tests (which don't support running against a running server).
+if meson.version().version_compare('>=0.57')
+  add_test_setup('default',
+    is_default: true,
+    exclude_suites: ['running'])
+  add_test_setup('running',
+    exclude_suites: ['temp-install', 'setup', 'tap'])
+  runningcheck = true
+else
+  runningcheck = false
+endif
+
 testwrap = files('src/tools/testwrap')
 
 foreach test_dir : tests
@@ -2917,18 +2932,27 @@ foreach test_dir : tests
 
       test_output = test_result_dir / test_dir['name'] / kind
 
+      # unless specified by the test, choose a non-conflicting database name,
+      # to avoid conflicts when running against existing server.
+      dbname = t.get('dbname',
+        'regression_@0@_@1@'.format(test_dir['name'], kind))
+
       test_command = [
         runner.full_path(),
         '--inputdir', t.get('inputdir', test_dir['sd']),
         '--expecteddir', t.get('expecteddir', test_dir['sd']),
         '--outputdir', test_output,
-        '--temp-instance', test_output / 'tmp_check',
         '--bindir', '',
         '--dlpath', test_dir['bd'],
         '--max-concurrent-tests=20',
-        '--port', testport.to_string(),
+        '--dbname', dbname,
       ] + t.get('regress_args', [])
 
+      test_command_tmp_install = test_command + [
+          '--temp-instance', test_output / 'tmp_check',
+          '--port', testport.to_string(),
+        ]
+
       if t.has_key('schedule')
         test_command += ['--schedule', t['schedule'],]
       endif
@@ -2943,7 +2967,6 @@ foreach test_dir : tests
       env.prepend('PATH', temp_install_bindir, test_dir['bd'])
 
       test_kwargs = {
-        'suite': [test_dir['name']],
         'priority': 10,
         'timeout': 1000,
         'depends': test_deps + t.get('deps', []),
@@ -2954,11 +2977,26 @@ foreach test_dir : tests
         python,
         args: testwrap_base + [
           '--testname', kind,
-          '--', test_command,
+          '--', test_command_tmp_install,
         ],
+        suite: [test_dir['name'], 'temp-install'],
         kwargs: test_kwargs,
       )
 
+      # some tests can't support running against running DB
+      if runningcheck and t.get('runningcheck', true)
+        test(test_dir['name'] / kind + '-running',
+          python,
+          args: testwrap_base + [
+            '--testname', kind,
+            '--', test_command,
+          ],
+          is_parallel: t.get('runningcheck-parallel', true),
+          suite: [test_dir['name'], 'running'],
+          kwargs: test_kwargs,
+        )
+      endif
+
       testport += 1
     elif kind == 'tap'
       if not tap_tests_enabled
@@ -2982,7 +3020,7 @@ foreach test_dir : tests
 
       test_kwargs = {
         'protocol': 'tap',
-        'suite': [test_dir['name']],
+        'suite': [test_dir['name'], 'tap'],
         'timeout': 1000,
         'depends': test_deps + t.get('deps', []),
         'env': env,

src/interfaces/ecpg/test/meson.build

@@ -85,6 +85,7 @@ tests += {
     'test_kwargs': {
       'depends': ecpg_test_dependencies,
     },
+    'dbname': 'ecpg1_regression,ecpg2_regression',
     'regress_args': ecpg_regress_args,
   },
 }

src/test/isolation/meson.build

@@ -67,5 +67,8 @@ tests += {
       'priority': 40,
       'timeout': 1000,
     },
+    # checks pg_locks etc
+    'runningcheck-parallel': false,
+    'dbname': 'isolation',
   },
 }

src/test/modules/commit_ts/meson.build

@@ -6,6 +6,9 @@ tests += {
     'sql': [
       'commit_timestamp',
     ],
+    # Disabled because these tests require "track_commit_timestamp = on",
+    # which typical runningcheck users do not have (e.g. buildfarm clients).
+    'runningcheck': false,
   },
   'tap': {
     'tests': [