meson: implement generated node support

Author: anarazel

src/backend/nodes/meson.build

@@ -1,17 +1,30 @@
 backend_sources += files(
   'bitmapset.c',
-  'copyfuncs.c',
-  'equalfuncs.c',
   'extensible.c',
   'list.c',
   'makefuncs.c',
   'nodeFuncs.c',
   'nodes.c',
-  'outfuncs.c',
   'params.c',
   'print.c',
   'read.c',
-  'readfuncs.c',
   'tidbitmap.c',
   'value.c',
 )
+
+# these include .c files generated in ../../include/nodes, seems nicer to not
+# add that as an include path for the whole backend
+nodefunc_sources = files(
+  'copyfuncs.c',
+  'equalfuncs.c',
+  'outfuncs.c',
+  'readfuncs.c',
+)
+nodefuncs = static_library('nodefuncs',
+  nodefunc_sources,
+  c_pch: pch_c_h,
+  dependencies: [backend_code],
+  kwargs: default_lib_args + {'install': false},
+  include_directories: include_directories('../../include/nodes'),
+)
+backend_link_with += nodefuncs

src/include/meson.build

@@ -104,11 +104,12 @@ install_headers(
   install_dir: dir_include_server,
 )
 
-subdir('utils')
-subdir('storage')
 subdir('catalog')
+subdir('nodes')
 subdir('parser')
 subdir('pch')
+subdir('storage')
+subdir('utils')
 
 header_subdirs = [
   'access',

src/include/nodes/meson.build

@@ -0,0 +1,49 @@
+node_support_input = [
+ 'nodes.h',
+ 'execnodes.h',
+ 'plannodes.h',
+ 'primnodes.h',
+ 'pathnodes.h',
+ 'extensible.h',
+ 'parsenodes.h',
+ 'replnodes.h',
+ 'value.h',
+ '../commands/trigger.h',
+ '../commands/event_trigger.h',
+ '../foreign/fdwapi.h',
+ '../access/amapi.h',
+ '../access/tableam.h',
+ '../access/tsmapi.h',
+ '../utils/rel.h',
+ 'supportnodes.h',
+ '../executor/tuptable.h',
+ 'lockoptions.h',
+ '../access/sdir.h',
+]
+
+node_support_output = [
+  'nodetags.h',
+  'outfuncs.funcs.c', 'outfuncs.switch.c',
+  'readfuncs.funcs.c', 'readfuncs.switch.c',
+  'copyfuncs.funcs.c', 'copyfuncs.switch.c',
+  'equalfuncs.funcs.c', 'equalfuncs.switch.c',
+]
+node_support_install = [
+  dir_include_server / 'nodes',
+  false, false,
+  false, false,
+  false, false,
+  false, false,
+]
+
+generated_nodes = custom_target('scan',
+  input: node_support_input,
+  output: node_support_output,
+  command: [
+    perl, files('../../backend/nodes/gen_node_support.pl'),
+    '-o', '@OUTDIR@',
+    '@INPUT@'],
+  install: true,
+  install_dir: node_support_install,
+)
+generated_headers += generated_nodes[0]