ExCSS/build.bat at master · bromike/ExCSS · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
@ECHO OFF

ECHO.
ECHO ==[Restoring packages]==
ECHO.
set nuGetDir=%~dp0.nuget
call "%nuGetDir%\nuget.exe" restore "%~dp0ExCSS.Unity.sln"
if ERRORLEVEL 1 exit 1

ECHO.
ECHO ==[Building library]==
ECHO.
set msBuildDir=%WINDIR%\Microsoft.NET\Framework\v4.0.30319
call "%msBuildDir%\msbuild.exe" ExCSS.Unity.sln  /p:Configuration=Release /l:FileLogger,Microsoft.Build.Engine;logfile=Manual_MSBuild_ReleaseVersion_LOG.log
if ERRORLEVEL 1 exit 1

ECHO.
ECHO ==[Run Debug unit tests]==
ECHO.
call .\nunit-console\nunit3-console.exe .\ExCSS.Tests\bin\DebugUnity35\ExCSS.Tests.dll
if ERRORLEVEL 1 exit 1

ECHO.
ECHO ==[Run Release unit tests]==
ECHO.
call .\nunit-console\nunit3-console.exe .\ExCSS.Tests\bin\ReleaseUnity35\ExCSS.Tests.dll
if ERRORLEVEL 1 exit 1

ECHO.
ECHO ==[Prepare DLLs for zipping]==
ECHO.
ECHO [Clear .\builds dir]
rmdir /S /Q .\builds
if ERRORLEVEL 1 exit 1

ECHO [Remove old builds.zip]
del /Q .\builds.zip

ECHO [Make .\builds\lib\net35 dir]
mkdir .\builds\lib\net35
if ERRORLEVEL 1 exit 1

ECHO [Copy files to .\builds\lib\net35 dir]
copy .\ExCSS\bin\ReleaseUnity35\*.* .\builds\lib\net35
if ERRORLEVEL 1 exit 1

ECHO.
ECHO ==[Zip files]==
ECHO.
call 7z.exe a .\builds.zip .\builds
if ERRORLEVEL 1 exit 1