bigShell/bigShell.nix at main · chaoky/bigShell · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
{
  pkgs,
  shellHook ? "",
  fishHook ? "",
  bashHook ? "",
  zshHook ? "",
  shell ? "bash",
  ...
}@attrs:

let
  input = builtins.removeAttrs attrs [
    "pkgs"
    "shellHook"
    "fishHook"
    "bashHook"
    "zshHook"
    "shell"
  ];
  shellName = if shell == "auto" then builtins.baseNameOf (builtins.getEnv "SHELL") else shell;
  wrapped = pkgs.writeShellScriptBin shellName (
    {
      fish = ''
        INIT=/tmp/bigShellNix
        mkdir -p $INIT

        printf "%s\n" \
          '${shellHook}' \
          '${fishHook}' \
        >$INIT/.fishrc

        exec ${pkgs.fish}/bin/fish --init-command="source $INIT/.fishrc" "$@"
      '';
      bash = ''
        INIT=/tmp/bigShellNix
        mkdir -p $INIT

        printf "%s\n" \
          "source $HOME/.bashrc" \
          '${shellHook}' \
          '${bashHook}' \
        >$INIT/.bashrc

        exec ${pkgs.bashInteractive}/bin/bash --init-file $INIT/.bashrc "$@"
      '';
      zsh = ''
        ZDOTDIR_=$ZDOTDIR
        if [[ -z "$ZDOTDIR_" ]]; then
          ZDOTDIR_=$HOME
        fi

        export ZDOTDIR=/tmp/bigShellNix
        mkdir -p $ZDOTDIR

        printf "%s\n" \
          "export ZDOTDIR=$ZDOTDIR_" \
          'source $ZDOTDIR/.zshrc' \
          '${shellHook}' \
          '${zshHook}' \
        >$ZDOTDIR/.zshrc

        exec ${pkgs.zsh}/bin/zsh "$@"
      '';
      "" = builtins.throw "shell not supported ${shellName}";
    }
    .${shellName}
  );
  override = {
    shellHook = ''
      export SHELL_NAME=${shellName}
      export SHELL=${wrapped}/bin/${shellName}
      exec $SHELL
    '';
  };
in

pkgs.mkShell (input // override)