Ameliorations rochefort (#20)

* Non-distinction scolaire/non-scolaire

* Exercices (part 1)

* Ajout Timestamps (1er jet) + exo course

* Suppression TODO

* Liens autres parties

* Fix broken HTML

* Switch to markdown for collapse

* Save reformatted code

* Save reformatted code

* Move file listing from DataTable to markdown list (try to be clearer)

* Wip test for summariser

* Compute summary

* Format

* Extract XmlSummariser module to file

* Separate dedicated Saxy part before adding more there

* Finalise tests

* Add < >

---------

Co-authored-by: Thibaut Barrère <thibaut.barrere@gmail.com>

Author: adurand-cs

lib/test/wip_test.exs

@@ -0,0 +1,56 @@
+# self-contained tests embryo
+
+Mix.install([
+  {:unzip, "~> 0.12.0"},
+  {:saxy, "~> 1.6"}
+])
+
+ExUnit.start()
+Code.require_file("../zip_support.ex", __DIR__)
+Code.require_file("../xml_support.ex", __DIR__)
+Code.require_file("../xml_summariser.ex", __DIR__)
+Code.require_file("../helpers.ex", __DIR__)
+
+defmodule Tests do
+  use ExUnit.Case
+
+  @folder_root Path.join(__DIR__, "../..")
+  @file_path "data/ca_rochefort_ocean-aggregated-netex-2025-03-03.zip"
+
+  def one!(list, regexp) do
+    list
+    |> Enum.filter(&(&1 =~ regexp))
+    |> Helpers.one!()
+  end
+
+  test "summarises XML binary" do
+    content = "<Root><Child/><Child/><Other/><Child/></Root>"
+    summary = XmlSummariser.summarise!(content)
+
+    assert summary == """
+           <Root>
+             (...) (x4)\
+           """
+  end
+
+  test "summarises XML stream" do
+    # useful to ensure we don't break the unzip/iodata/binary dance
+    zip =
+      @file_path
+      |> Path.expand(@folder_root)
+      |> ZipSupport.open_zip!()
+
+    filename =
+      zip
+      |> ZipSupport.list_zip_entries()
+      |> one!(~r/commun/)
+
+    output =
+      zip
+      |> Unzip.file_stream!(filename)
+      |> Stream.map(&IO.iodata_to_binary(&1))
+      |> XmlSummariser.summarise!()
+
+    assert output =~ ~r/\<Line\> \(x14\)/
+  end
+end

lib/xml_summariser.ex

@@ -0,0 +1,70 @@
+# TODO: port to xmerl_sax_handler to reduce external dependencies
+# NOTE: for much larger docs later, this is the way https://github.com/qcam/saxy/pull/100
+defmodule XmlSummariser do
+  # Works with file/unzip streams
+  def summarise!(stream) when is_struct(stream, Stream) or is_list(stream) do
+    {:ok, output} =
+      stream
+      |> Saxy.parse_stream(XmlSummariser.Sax.Handler, [])
+
+    output
+  end
+
+  # Raw binary version (useful for simple string passing)
+  def summarise!(binary) when is_binary(binary) do
+    summarise!([binary])
+  end
+
+  defmodule Sax.Handler do
+    @moduledoc """
+    A `Saxy` handler useful to provide a textual résumé of a XML.
+    """
+
+    @behaviour Saxy.Handler
+
+    def format_line([item]), do: item
+    def format_line(items = [item | _tail]), do: "#{item} (x#{items |> length})"
+
+    def handle_event(:start_document, _options, []) do
+      {:ok, %{level: 0, output: []}}
+    end
+
+    def handle_event(:end_document, _options, state) do
+      output =
+        state.output
+        |> Enum.chunk_by(& &1)
+        |> Enum.map(&format_line(&1))
+        |> Enum.join("\n")
+
+      {:ok, output}
+    end
+
+    def handle_event(:start_element, {name, _attributes}, state) do
+      indent = String.duplicate("  ", state.level)
+
+      state =
+        state
+        |> Map.update!(:level, &(&1 + 1))
+
+      state =
+        state
+        |> Map.update!(:output, fn output ->
+          # TODO: support customisation, this is currently hardcoded to presentation specific needs
+          cond do
+            state.level > 5 -> output
+            state.level in 2..3 -> output ++ [indent <> "(...)"]
+            true -> output ++ [indent <> "<" <> name <> ">"]
+          end
+        end)
+
+      {:ok, state}
+    end
+
+    def handle_event(:end_element, _, state) do
+      state = state |> Map.update!(:level, &(&1 - 1))
+      {:ok, state}
+    end
+
+    def handle_event(_, _, state), do: {:ok, state}
+  end
+end