GTFS-diff : Améliorations présentations des résultats - structure des fichiers (#4487)

Author: ptitfred

apps/transport/client/stylesheets/components/_gtfs_diff.scss

@@ -163,6 +163,10 @@
       overflow: scroll;
     }
   }
+
+  .symbol {
+    margin-inline: 6px;
+  }
 }
 
 @media (max-width: 749px) {

apps/transport/lib/transport_web/live/gtfs_diff_explain.ex

@@ -14,15 +14,73 @@ defmodule TransportWeb.GTFSDiffExplain do
         |> Map.update("identifier", %{}, &try_jason_decode(&1))
 
       []
-      |> explanation_add_file(diff)
-      |> explanation_delete_file(diff)
       |> explanation_update_stop_name(diff)
       |> explanation_stop_wheelchair_access(diff)
       |> explanation_update_stop_longitude(diff)
       |> explanation_update_stop_latitude(diff)
     end)
   end
 
+  @doc """
+  Analyses structural changes of diff, focusing on column changes and if the file has been created or deleted.
+
+  It ignores the row changes.
+  """
+  def structural_changes(diffs) do
+    Enum.reduce(diffs, %{}, fn action, acc ->
+      if Map.get(action, "target") == "row" do
+        acc
+      else
+        new_diff = structural_change(action)
+
+        Map.update(acc, Map.get(action, "file"), [new_diff], &merge_diffs(new_diff, &1))
+      end
+    end)
+  end
+
+  defp structural_change(%{"target" => "file", "action" => action}) do
+    case action do
+      "add" -> :added_file
+      "delete" -> :deleted_file
+    end
+  end
+
+  defp structural_change(%{"target" => "column", "action" => action, "identifier" => identifier}) do
+    %{"column" => column} = Jason.decode!(identifier)
+
+    case action do
+      "add" -> {:added_columns, [column]}
+      "delete" -> {:deleted_columns, [column]}
+    end
+  end
+
+  defp merge_diffs({column_action, _} = new_diff, diffs) do
+    existing_action =
+      Enum.find(diffs, fn elem ->
+        case elem do
+          {^column_action, _} -> true
+          _ -> false
+        end
+      end)
+
+    if existing_action do
+      Enum.map(diffs, &merge_existing_actions(new_diff, &1))
+    else
+      [new_diff | diffs]
+    end
+  end
+
+  defp merge_diffs(new_diff, diffs) do
+    [new_diff | diffs]
+  end
+
+  defp merge_existing_actions({column_action, columns1}, elem) do
+    case elem do
+      {^column_action, columns2} -> {column_action, Enum.sort(columns1 ++ columns2)}
+      _ -> elem
+    end
+  end
+
   @doc """
   Creates a summary of a given GTFS Diff
 

apps/transport/lib/transport_web/live/gtfs_diff_select_live.ex

@@ -279,10 +279,12 @@ defmodule TransportWeb.Live.GTFSDiffSelectLive do
   defp update_results_with_diff(socket, diff) do
     diff_summary = diff |> GTFSDiffExplain.diff_summary()
     diff_explanations = diff |> GTFSDiffExplain.diff_explanations() |> drop_empty()
+    structural_changes = diff |> GTFSDiffExplain.structural_changes()
 
     update_many(socket, :results, [
       set(:diff_summary, diff_summary),
-      set(:diff_explanations, diff_explanations)
+      set(:diff_explanations, diff_explanations),
+      set(:structural_changes, structural_changes)
     ])
   end
 

apps/transport/lib/transport_web/live/gtfs_diff_select_live/analysis.ex

@@ -2,7 +2,7 @@ defmodule TransportWeb.Live.GTFSDiffSelectLive.Analysis do
   @moduledoc """
   Analysis step of the GTFS diff tool.
   """
-  use Phoenix.LiveView
+  use Phoenix.Component
   use TransportWeb.InputHelpers
   import TransportWeb.Gettext
 

apps/transport/lib/transport_web/live/gtfs_diff_select_live/differences.ex

@@ -0,0 +1,238 @@
+defmodule TransportWeb.Live.GTFSDiffSelectLive.Differences do
+  @moduledoc """
+  Differences of the selected file.
+  """
+  use Phoenix.Component
+  import TransportWeb.Gettext
+  import TransportWeb.Live.GTFSDiffSelectLive.GTFSSpecification
+
+  def differences(
+        %{diff_summary: _, selected_file: _, diff_explanations: _, profile: _, structural_changes: _} = assigns
+      ) do
+    ~H"""
+    <div class="main">
+      <.file_description selected_file={@selected_file} />
+      <.structural_differences
+        :if={Map.get(@structural_changes, @selected_file)}
+        selected_file={@selected_file}
+        structural_changes={Map.get(@structural_changes, @selected_file)}
+      />
+      <.diff_summaries_for_file diff_summary={@diff_summary} selected_file={@selected_file} profile={@profile} />
+      <%= if assigns[:diff_explanations] do %>
+        <% active_explanations =
+          @diff_explanations
+          |> Enum.filter(fn {file, _} -> file == @selected_file end)
+          |> Enum.map(fn {_, explanation} -> explanation end) %>
+        <.detailed_explanations :if={not Enum.empty?(active_explanations)} active_explanations={active_explanations} />
+      <% end %>
+    </div>
+    """
+  end
+
+  defp structural_differences(%{structural_changes: structural_changes, selected_file: _} = assigns) do
+    assigns =
+      assigns
+      |> assign(file_differences: Enum.filter(structural_changes, &file_difference?/1))
+      |> assign(column_differences: Enum.filter(structural_changes, &column_difference?/1))
+
+    ~H"""
+    <.file_differences
+      selected_file={@selected_file}
+      file_differences={@file_differences}
+      column_differences={@column_differences}
+      file_criteria={:added_file}
+      column_criteria={:added_columns}
+    />
+    <.file_differences
+      selected_file={@selected_file}
+      file_differences={@file_differences}
+      column_differences={@column_differences}
+      file_criteria={:deleted_file}
+      column_criteria={:deleted_columns}
+    />
+    <.columns_differences
+      selected_file={@selected_file}
+      file_differences={@file_differences}
+      column_differences={@column_differences}
+      criteria={:added_columns}
+    />
+    <.columns_differences
+      selected_file={@selected_file}
+      file_differences={@file_differences}
+      column_differences={@column_differences}
+      criteria={:deleted_columns}
+    />
+    """
+  end
+
+  defp file_difference?(:added_file), do: true
+  defp file_difference?(:deleted_file), do: true
+  defp file_difference?(_), do: false
+
+  defp file_differences(
+         %{file_differences: _, column_differences: _, selected_file: _, file_criteria: _, column_criteria: _} = assigns
+       ) do
+    ~H"""
+    <p :if={@file_differences == [@file_criteria]}>
+      <i class={pick_symbol(@file_criteria)}></i>
+      <%= pick_file_message(@file_criteria, count_column_differences(@column_differences, @column_criteria)) %>
+    </p>
+    <.columns_list
+      :if={@file_differences == [@file_criteria]}
+      selected_file={@selected_file}
+      column_differences={@column_differences}
+      criteria={@column_criteria}
+    />
+    """
+  end
+
+  defp pick_file_message(:added_file, count),
+    do:
+      dngettext(
+        "validations",
+        "file added with %{count} new column:",
+        "file added with %{count} new columns:",
+        count
+      )
+
+  defp pick_file_message(:deleted_file, count),
+    do:
+      dngettext(
+        "validations",
+        "file deleted along with %{count} column:",
+        "file deleted along with %{count} columns:",
+        count
+      )
+
+  defp column_difference?({:added_columns, _}), do: true
+  defp column_difference?({:deleted_columns, _}), do: true
+  defp column_difference?(_), do: false
+
+  defp columns_differences(%{file_differences: _, column_differences: _, criteria: _, selected_file: _} = assigns) do
+    ~H"""
+    <p :if={@file_differences == [] && Keyword.get(@column_differences, @criteria)}>
+      <i class={pick_symbol(@criteria)}></i>
+      <%= pick_column_message(@criteria, count_column_differences(@column_differences, @criteria)) %>
+    </p>
+    <.columns_list
+      :if={@file_differences == [] && Keyword.get(@column_differences, @criteria)}
+      selected_file={@selected_file}
+      column_differences={@column_differences}
+      criteria={@criteria}
+    />
+    """
+  end
+
+  defp columns_list(%{column_differences: _, criteria: _, selected_file: _} = assigns) do
+    ~H"""
+    <ul>
+      <li :for={column <- Keyword.get(@column_differences, @criteria)}>
+        <code><%= column %></code>
+        <span :if={not standard_column?(@selected_file, column)}>
+          <i class="symbol fa fa-warning orange"></i> <%= dgettext("validations", "non standard column") %>
+        </span>
+      </li>
+    </ul>
+    """
+  end
+
+  defp count_column_differences(column_differences, criteria) do
+    column_differences |> Keyword.get(criteria) |> Enum.count()
+  end
+
+  defp pick_column_message(:added_columns, count),
+    do: dngettext("validations", "Added %{count} column:", "Added %{count} columns:", count)
+
+  defp pick_column_message(:deleted_columns, count),
+    do: dngettext("validations", "Deleted %{count} column:", "Deleted %{count} columns:", count)
+
+  defp pick_symbol(:added_columns), do: "symbol fa fa-square-plus green"
+  defp pick_symbol(:added_file), do: "symbol fa fa-square-plus green"
+  defp pick_symbol(:deleted_columns), do: "symbol fa fa-square-minus red"
+  defp pick_symbol(:deleted_file), do: "symbol fa fa-square-minus red"
+
+  defp diff_summaries_for_file(%{selected_file: _, diff_summary: _, profile: _} = assigns) do
+    ~H"""
+    <p><%= dgettext("validations", "Row changes:") %></p>
+    <ul>
+      <.diff_summary_for_file
+        :for={{nature, translation, css_class} <- diff_natures()}
+        summary={@diff_summary[nature]}
+        translation={translation}
+        selected_file={@selected_file}
+        class={css_class}
+      />
+    </ul>
+    <.partial_difference_warning :if={@selected_file not in Transport.GTFSDiff.files_to_analyze(@profile)} />
+    """
+  end
+
+  defp diff_summary_for_file(%{summary: _, selected_file: _, translation: _, class: _} = assigns) do
+    ~H"""
+    <%= for {{file, _nature, target}, n} <- @summary || [] do %>
+      <li :if={file == @selected_file && target == "row"}>
+        <span class={@class}><%= @translation %></span>&nbsp;<%= translate_target(target, n) %>
+      </li>
+    <% end %>
+    """
+  end
+
+  defp partial_difference_warning(%{} = assigns) do
+    ~H"""
+    <div class="notification warning">
+      <%= dgettext(
+        "validations",
+        "Row changes have not been analyzed for this file. We suggest you dive into both GTFS files for more details."
+      ) %>
+    </div>
+    """
+  end
+
+  defp diff_natures do
+    [
+      {"add", dgettext("validations", "added"), "green"},
+      {"update", dgettext("validations", "updated"), "orange"},
+      {"delete", dgettext("validations", "deleted"), "red"}
+    ]
+  end
+
+  defp detailed_explanations(%{active_explanations: _} = assigns) do
+    ~H"""
+    <p>
+      <%= dgettext("validations", "Notable changes:") %>
+      <ul>
+        <li :for={explanation <- @active_explanations}><%= explanation %></li>
+      </ul>
+    </p>
+    """
+  end
+
+  @doc """
+  iex> Gettext.put_locale("en")
+  iex> translate_target("file", 1)
+  "1 file"
+  iex> translate_target("file", 3)
+  "3 files"
+  iex> translate_target("row", 1)
+  "1 row"
+  iex> translate_target("row", 3)
+  "3 rows"
+  iex> Gettext.put_locale("fr")
+  iex> translate_target("file", 1)
+  "1 fichier"
+  iex> translate_target("file", 3)
+  "3 fichiers"
+  iex> translate_target("row", 1)
+  "1 ligne"
+  iex> translate_target("row", 3)
+  "3 lignes"
+  """
+  def translate_target(target, n) do
+    case target do
+      "file" -> dngettext("validations", "%{count} file", "%{count} files", n)
+      "row" -> dngettext("validations", "%{count} row", "%{count} rows", n)
+      "column" -> dngettext("validations", "%{count} column", "%{count} columns", n)
+      _ -> "#{n} #{target}#{if n > 1, do: "s"}"
+    end
+  end
+end