colcheck

#!/usr/bin/awk -f
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program. If not, see <http://www.gnu.org/licenses/>.
#
# Copyright 2014 Jeremy Brubaker <jbru362@gmail.com>
#
# abstract: check consistency of columns
#
# input: rows of numbers and strings
# output: lines with format different than first line
#

NR == 1 {
    nfld = NF
    for (i = 1; i <= NF; i++)
        type[i] = isnum($i)

    printf("first line contains %d fields\n", nfld)
    printf("%s", "fields are: ")
    for (i = 1; i <= NF; i++)
        printf("%s ", type[i] ? "NUM" : "STR")
    print ""
    print ""
}

{   if (NF != nfld) {
        printf("%d: %s : %d fields\n",
           NR, $0, NF)
    }
    for (i = 1; i <= (NF <= nfld ? NF : nfld); i++)
        if (isnum($i) != type[i]) {
            printf("%d: %s : field %d not a %s\n",
                   NR, $0, i, type[i] ? "number" : "string")
        }
}

function isnum(n) {
    return n ~ /^[+-]?([0-9]+[.]?[0-9]*|[.][0-9]+)([eE][+-]?[0-9]*)?$/
}