How to derive Show and other classes for Barbies.Bare types

[axman6]

I'm looking at the example of defining a BareB compatible type in Barbies.Bare and the example tantalisingly has the following

data SignUpForm t f
  = SignUpForm
      { username  :: Wear t f String,
      , password  :: Wear t f String
      , mailingOk :: Wear t f Bool
      }
 instance FunctorB (SignUpForm Covered)
 instance TraversableB (SignUpForm Covered)
 ...,
 instance BareB SignUpForm

I'd love to see the ..., filled in to give at least one example of deriving a class like Show or Eq. I've managed to get as far as

data Bareable t f
  = Bareable
    { bareName :: Wear t f String
    , bareAge :: Wear t f Int
    }
  deriving (Generic)

instance BareB Bareable
instance FunctorB (Bareable Covered)
instance TraversableB (Bareable Covered)
instance ApplicativeB (Bareable Covered)
instance DistributiveB (Bareable Covered)

deriving instance AllBF Show f (Bareable Bare) => Show (Bareable Bare f)

but I can't figure out how I'd define an instance for Show (Bareable Covered f) as well. If it's at all interesting, I'm currently working on something which might turn into a package eventually, which provides (hopefully) efficient conversion between Vector (b Identity) and b Vector (including Unboxed vectors where if all fields are compatible) for struct-of-arrays of any Barbie type, and being able to show the result would nice a nice to have.

[jcpetruzza]

Hi @axman6

You were quite close. In order to be able to use AllBF, you need to derive ConstraintsB as well. Also, for Bareable Bare f, nothing depends on f, so you don't even need the constraint:

instance ConstraintsB (Bareable Covered)
deriving instance Show (Bareable Bare f)
deriving instance AllBF Show f (Bareable Covered) => Show (Bareable Covered f)

And then I get

ghci> let x = Bareable "foo" 42 :: Bareable Bare Identity
ghci> let y = Bareable (Just "foo") (Just 42) :: Bareable Covered Maybe
ghci> show x
"Bareable {bareName = \"foo\", bareAge = 42}"
ghci> show y
"Bareable {bareName = Just \"foo\", bareAge = Just 42}"
ghci> 

Hope that helps!

I'm currently working on something which might turn into a package eventually, which provides (hopefully) efficient conversion between Vector (b Identity) and b Vector

Nice, basing struct-of-arrays on this makes sense, and makes a good example of DistributiveB too, I think?

[axman6]

So close! Yeah I did think the constraints of f didn't make sense but I didn't think of removing it - obvious in hindsight. And of course I need ConstraintsB too.

I think it would be good to have these instances as examples in the module just to save others the pain.

Yeah the SOA in its most basic form is just btraverse' but I think it creates more intermediate vectors than I’d like so I wrote the explicit ST based mutable construction.

I had a think about it overnight and realised that I think it's trivial to make an Unbox instance for all barbies types where the fields have an Unbox instance. I'll see if I can make that work today.