module.nix

{ config, lib, pkgs, ... }:

with lib;

let
  inherit (lib) types mkOption mkEnableOption;
  cfg = config.nixMacs;
  logoImage = "${./config/nix_emacs_logo_small.png}";

  exwmQwerty = ./config/exwm-qwerty.el;
  exwmColemak = ./config/exwm-colemak.el;

  customEorg = pkgs.runCommand "e.org" {} ''
    substitute ${./config/e.org} $out \
      --replace "~/Pictures/nix_emacs_logo_small.png" "${logoImage}"
  '';

  filianThemeOrg = ''
    * Theme/Colorscheme
    #+BEGIN_SRC emacs-lisp
    (load-theme 'filian t)
    #+END_SRC
  '';

  jungleThemeOrg = ''
    * Theme/Colorscheme
    #+BEGIN_SRC emacs-lisp
    (load-theme 'jungle t)
    #+END_SRC
  '';

  jungleThemeVibrantOrg = ''
    * Theme/Colorscheme
    #+BEGIN_SRC emacs-lisp
    (load-theme 'jungle-vibrant t)
    #+END_SRC
  '';

  acmeThemeOrg = ''
    * Theme/Colorscheme
    #+BEGIN_SRC emacs-lisp
    (load-theme 'acme t)
    #+END_SRC
  '';

  plan9ThemeOrg = ''
    * Theme/Colorscheme
    #+BEGIN_SRC emacs-lisp
    (load-theme 'plan9 t)
    #+END_SRC
  '';

  fuwamocoThemeOrg = ''
    * Theme/Colorscheme
    #+BEGIN_SRC emacs-lisp
    (load-theme 'fuwamoco t)
    #+END_SRC
  '';

  marnieThemeOrg = ''
    * Theme/Colorscheme
    #+BEGIN_SRC emacs-lisp
    (load-theme 'marnie t)
    #+END_SRC
  '';

  guixThemeOrg = ''
    * Theme/Colorscheme
    #+BEGIN_SRC emacs-lisp
    (load-theme 'guix t)
    #+END_SRC
  '';

  gruvboxThemeOrg = ''
    * Theme/Colorscheme
    #+BEGIN_SRC emacs-lisp
    (load-theme 'gruvbox-dark-medium t)
    #+END_SRC
  '';

  cappuccinoNoirThemeOrg = ''
    * Theme/Colorscheme
    #+BEGIN_SRC emacs-lisp
    (load-theme 'cappuccino-noir t)
    #+END_SRC
  '';

  templeosFont = pkgs.callPackage ./config/fonts/templeos/default.nix {};
  templeosThemeOrg = ''
    * Theme/Colorscheme
    #+BEGIN_SRC emacs-lisp
    (load-theme 'temple-os t)
    (set-face-attribute 'default nil :font "TempleOS-10")
    #+END_SRC
  '';

  hoon-mode = pkgs.stdenv.mkDerivation {
    pname = "hoon-mode";
    version = "latest";
    src = pkgs.fetchFromGitHub {
      owner = "urbit";
      repo  = "hoon-mode.el";
      #rev   = "main";
      rev = "master";
      sha256 = "sha256-gOmh3+NxAIUa2VcmFFqavana8r6LT9VmnrJOFLCF/xw=";
    };
    nativeBuildInputs = [ pkgs.emacs ]; # or just pkgs.emacs for byte-compiling
    # If there is no build system, skip straight to install.
    buildPhase = "true";
    installPhase = ''
      install -d $out/share/emacs/site-lisp
      install -m644 hoon-mode.el hoon-dictionary.json $out/share/emacs/site-lisp/
    '';
  };

  exwmFixed = pkgs.emacsPackages.trivialBuild rec {
    pname = "exwm";
    version = "0.34";
    src = pkgs.fetchFromGitHub {
      owner = "emacs-exwm";
      repo = "exwm";
      rev = "0.34";
      sha256 = "sha256-7Z8vkmkMFsZnBfiadoKNiaJd1+RvCr2OxW1EiY9xY4s=";
    };
    packageRequires = [
      pkgs.emacsPackages.compat
      pkgs.emacsPackages.xelb
    ];
  };

  includedPackages = epkgs: with epkgs; [
    use-package
    color-theme-sanityinc-tomorrow
    company
    emms
    fancy-dabbrev
    lsp-mode
    lsp-ui
    markdown-mode
    multi-term
    multiple-cursors
    nix-buffer
    nix-mode
    rainbow-mode
    rust-mode
    rustic
    wttrin
    hydra
    all-the-icons
    haskell-mode
    arduino-mode
    flycheck
    gruvbox-theme
    bongo
    impatient-mode
    simple-httpd
    hoon-mode
    exwmFixed
    compat
    xelb
    nickel-mode
    iedit
    anzu
    visual-regexp
    try
    sudo-edit
    pdf-tools
    beacon
    doom-modeline
    vim-tab-bar
    erc-image
    dired-subtree
  ] ++ (cfg.extraPackages epkgs);

  configuredEmacsX11 = pkgs.emacs.pkgs.withPackages includedPackages;
  configuredEmacsWayland = pkgs.emacs-pgtk.pkgs.withPackages includedPackages;

  primaryEmacs = if (cfg.wayland.enable && !cfg.wayland.separatePackage) then configuredEmacsWayland else configuredEmacsX11;

  nixmacs = pkgs.writeShellScriptBin cfg.binaryName ''
    unset EMACSLOADPATH
    exec ${primaryEmacs}/bin/emacs "$@"
  '';

  nixmacs-client = pkgs.writeShellScriptBin "${cfg.binaryName}-client" ''
    exec ${primaryEmacs}/bin/emacsclient "$@"
  '';

  nixmacs-wayland = pkgs.writeShellScriptBin "${cfg.binaryName}-wayland" ''
    unset EMACSLOADPATH
    exec ${configuredEmacsWayland}/bin/emacs "$@"
  '';

  nixmacs-wayland-client = pkgs.writeShellScriptBin "${cfg.binaryName}-wayland-client" ''
    exec ${configuredEmacsWayland}/bin/emacsclient "$@"
  '';

  nixmacs-pager = pkgs.writeShellScriptBin "${cfg.binaryName}-pager" ''
    #!/usr/bin/env zsh

    tmp=$(mktemp)

    cat > $tmp

    ${primaryEmacs}/bin/emacsclient -nw --eval "
    (with-current-buffer (find-file \"$tmp\")
      (view-mode)
      (goto-char (point-min))
      (add-hook 'kill-buffer-hook (lambda () (ignore-errors (delete-file \"$tmp\")))))
    "
  '';
in {
  options.nixMacs = {
    enable = mkEnableOption "custom Emacs configuration";
    extraPackages = mkOption {
      type = types.functionTo (types.listOf types.package);
      default = epkgs: with epkgs; [];
      description = "Extra Emacs packages to install";
    };
    binaryName = mkOption {
      type = types.str;
      default = "nixmacs";
      description = "Name of the Emacs binary command";
    };
    wayland = {
      enable = mkOption {
        type = types.bool;
        default = true;
        example = false;
        description = "Whether to enable Wayland Compatible NixMacs or not.";
      };
      separatePackage = mkOption {
        type = types.bool;
        default = true;
        example = false;
        description = "Whether to install the Wayland Package as a dual Package or not.";
      };
    };
    themes = {
      jungle = mkOption {
        type = types.bool;
        default = false;
        example = true;
        description = "Whether to enable or disable the builtin Jungle Theme/Colorscheme";
      };
      filian = mkOption {
        type = types.bool;
        default = true;
        example = true;
        description = "Whether to enable or disable the builtin Filian Theme/Colorscheme (based on Jungle Vibrant).";
      };
      jungleVibrant = mkOption {
        type = types.bool;
        default = false;
        example = true;
        description = "Whether to enable or disable the builtin Jungle (Vibrant) Theme/Colorscheme";
      };
      fuwamoco = mkOption {
        type = types.bool;
        default = false;
        example = true;
        description = "Whether to enable or disable the builtin Fuwamoco Theme/Colorscheme";
      };
      plan9 = mkOption {
        type = types.bool;
        default = false;
        example = true;
        description = "Whether to enable or disable the builtin Plan9 Theme/Colorscheme";
      };
      marnie = mkOption {
        type = types.bool;
        default = false;
        example = true;
        description = "Whether to enable or disable the builtin Marnie Theme/Colorscheme";
      };
      gruvbox = mkOption {
        type = types.bool;
        default = false;
        example = true;
        description = "Whether to enable or disable the builtin Gruvbox Theme/Colorscheme";
      };
      templeos = mkOption {
        type = types.bool;
        default = false;
        example = true;
        description = "Whether to enable or disable the builtin TempleOS Theme/Colorscheme";
      };
      guix = mkOption {
        type = types.bool;
        default = false;
        example = true;
        description = "Whether to enable or disable the builtin Guix Theme/Colorscheme";
      };
      cappuccinoNoir = mkOption {
        type = types.bool;
        default = false;
        example = true;
        description = "Whether to enable or disable the builtin Cappuccino Noir Theme/Colorscheme";
      };
      acme = mkOption {
        type = types.bool;
        default = false;
        example = true;
        description = "Whether to enable or disable the builtin Acme Theme/Colorscheme";
      };
      installAll = mkOption {
        type = types.bool;
        default = false;
        example = true;
        description = "Install all themes for Manual Application";
      };
    };
    exwm = {
      enable = mkOption {
        type = types.bool;
        default = false;
        description = "Enable EXWM Configuration";
      };
      layout = mkOption {
        type = types.enum [ "qwerty" "colemak" ];
        default = "qwerty";
        description = "Keyboard Layout for EXWM";
      };
    };
  };

  config = mkIf cfg.enable {
    assertions = [
      {
        assertion = (lib.count (x: x) [
          cfg.themes.fuwamoco
          cfg.themes.marnie
          cfg.themes.gruvbox
          cfg.themes.guix
          cfg.themes.templeos
          cfg.themes.cappuccinoNoir
          cfg.themes.acme
          cfg.themes.plan9
          cfg.themes.jungle
          cfg.themes.jungleVibrant
          cfg.themes.filian
        ]) <= 1;
        message = "Error: Only one Theme/Colorscheme can be enabled at a time!";
      }
    ];

    home.sessionVariables = {
      NIXMACS_LOGO_PATH = logoImage;
    } // (optionalAttrs cfg.exwm.enable {
      NIXMACS_EXWM_LAYOUT = cfg.exwm.layout;
    });

    home.packages = [
      pkgs.rust-analyzer
      pkgs.zathura
      pkgs.mpv
      nixmacs
      nixmacs-client
      nixmacs-pager
    ]
    ++ lib.optionals (cfg.wayland.enable && cfg.wayland.separatePackage) [
      nixmacs-wayland
      nixmacs-wayland-client
    ]
    ++ lib.optional cfg.themes.templeos templeosFont;

    home.file.".emacs" = {
      text = ''
        (let ((orgfile (expand-file-name "~/.nixmacs/config/e.org"))
              (elfile  (expand-file-name "~/.nixmacs/config/e.el")))
          (when (or (not (file-exists-p elfile))
                    (file-newer-than-file-p orgfile elfile))
            (require 'org)
            ;; Force tangling to the specific elfile path
            (org-babel-tangle-file orgfile elfile))

          ;; Safety check: only load if the file actually exists now
          (if (file-exists-p elfile)
              (load-file elfile)
            (message "Warning: %s could not be generated!" elfile)))
      '';
    };

    # Use the MODIFIED e.org with substituted path
    home.file.".nixmacs/config/e.org" = {
      text = builtins.readFile customEorg
        + optionalString cfg.themes.filian filianThemeOrg
        + optionalString cfg.themes.fuwamoco fuwamocoThemeOrg
        + optionalString cfg.themes.marnie marnieThemeOrg
        + optionalString cfg.themes.cappuccinoNoir cappuccinoNoirThemeOrg
        + optionalString cfg.themes.gruvbox gruvboxThemeOrg
        + optionalString cfg.themes.guix guixThemeOrg
        + optionalString cfg.themes.acme acmeThemeOrg
        + optionalString cfg.themes.plan9 plan9ThemeOrg
        + optionalString cfg.themes.jungle jungleThemeOrg
        + optionalString cfg.themes.jungleVibrant jungleThemeVibrantOrg
        + optionalString cfg.themes.templeos templeosThemeOrg;
    };

    # Install Themes
    home.file.".nixmacs/themes/plan9-theme.el" = mkIf (cfg.themes.plan9 || cfg.themes.installAll) {
      source = ./config/themes/plan9-theme.el;
    };
    home.file.".nixmacs/themes/jungle-theme.el" = mkIf (cfg.themes.jungle || cfg.themes.installAll) {
      source = ./config/themes/jungle-theme.el;
    };
    home.file.".nixmacs/themes/jungle-vibrant-theme.el" = mkIf (cfg.themes.jungleVibrant || cfg.themes.installAll) {
      source = ./config/themes/jungle-vibrant-theme.el;
    };
    home.file.".nixmacs/themes/acme-theme.el" = mkIf (cfg.themes.acme || cfg.themes.installAll) {
      source = ./config/themes/acme-theme.el;
    };
    home.file.".nixmacs/themes/guix-theme.el" = mkIf (cfg.themes.guix || cfg.themes.installAll) {
      source = ./config/themes/guix-theme.el;
    };
    home.file.".nixmacs/themes/fuwamoco-theme.el" = mkIf (cfg.themes.fuwamoco || cfg.themes.installAll) {
      source = ./config/themes/fuwamoco-theme.el;
    };
    home.file.".nixmacs/themes/marnie-theme.el" = mkIf (cfg.themes.marnie || cfg.themes.installAll) {
      source = ./config/themes/marnie-theme.el;
    };
    home.file.".nixmacs/themes/temple-os-theme.el" = mkIf (cfg.themes.templeos || cfg.themes.installAll) {
      source = ./config/themes/temple-os-theme.el;
    };
    home.file.".nixmacs/themes/cappuccino-noir-theme.el" = mkIf (cfg.themes.cappuccinoNoir || cfg.themes.installAll) {
      source = ./config/themes/cappuccino-noir-theme.el;
    };
    home.file.".nixmacs/themes/filian-theme.el" = mkIf (cfg.themes.filian || cfg.themes.installAll) {
      source = ./config/themes/filian-theme.el;
    };

    # EXWM Config File
    home.file.".nixmacs/config/exwm.el" = mkIf cfg.exwm.enable {
      source = if cfg.exwm.layout == "colemak" then exwmColemak else exwmQwerty;
    };
  };
}