persp-sort 'created in ascending order

[ispringle]

Wondering if there's a way to order perspectives by creation, in ascending order. So the first persp is 1, than a new one is created and it remains one and the new one is 2. Each new perspective created would just get added as the next number, so the third would be 3, etc.

Currently persp-sort 'created sets the order in descending order, newest first, which means when you add or remove a perspective the number changes. Ascending would keep them the same number, until one is deleted and they get moved up one.

[ispringle]

Took a look at the source and came up with this config:

(use-package perspective
  :general
  ("C-x k" #'persp-kill-buffer*)
  :init
  (setq persp-mode-prefix-key (kbd "C-z"))
  :custom
  (persp-sort 'oldest)
  (persp-state-default-file
   (expand-file-name "persp-state" minimal-emacs-user-directory))
  :hook
  (elpaca-after-init . persp-mode)
  (kill-emacs . persp-state-save)
  :config
  (defun persp-names ()
    "Return a list of the names of all perspectives on the `selected-frame'."
    (let ((persps (hash-table-values (perspectives-hash))))
      (cond ((eq persp-sort 'name)
             (sort (mapcar 'persp-name persps) 'string<))
            ((eq persp-sort 'access)
             (mapcar 'persp-name
                     (sort persps
                           (lambda (a b)
                             (time-less-p (persp-last-switch-time b)
                                          (persp-last-switch-time a))))))
            ((eq persp-sort 'created)
             (mapcar 'persp-name
                     (sort persps
                           (lambda (a b)
                             (time-less-p (persp-created-time b)
                                          (persp-created-time a))))))
            ((eq persp-sort 'oldest)
             (mapcar 'persp-name
                     (sort persps
                           (lambda (a b)
                             (time-less-p (persp-created-time a)
                                          (persp-created-time b)))))))))
  (with-eval-after-load 'consult
    (consult-customize consult--source-buffer :hidden t :default nil)
    (add-to-list 'consult-buffer-sources persp-consult-source)))

@nex3 would this be something you'd be willing to see me create a PR for?

[nex3]

I'm not actively maintaining this anymore, you want to ask @gcv!

[gcv]

Hi @nex3!

@ispringle: Your approach is to add a new sort order to persp-names, right? I think that’s fine. You should also add ’oldest to the persp-sort definition. Feel free to send over a PR.

[ispringle]

Great, I created #224 to add this.