optimism/op-program/justfile at dev · okx/optimism · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
import '../justfiles/go.just'

# Host ldflags: uses VERSION which can vary
_HOST_LDFLAGS := "'" + trim(
    "-X main.GitCommit=" + GITCOMMIT + " " + \
    "-X main.GitDate=" + GITDATE + " " + \
    "-X github.com/ethereum-optimism/optimism/op-program/version.Version=" + VERSION + " " + \
    "-X github.com/ethereum-optimism/optimism/op-program/version.Meta=" + VERSION_META + " " + \
    "") + "'"

# Client ldflags: ALWAYS v0.0.0 for reproducibility
_CLIENT_LDFLAGS := "'" + trim(
    "-X main.GitCommit=" + GITCOMMIT + " " + \
    "-X main.GitDate=" + GITDATE + " " + \
    "-X github.com/ethereum-optimism/optimism/op-program/version.Version=v0.0.0" + " " + \
    "-X github.com/ethereum-optimism/optimism/op-program/version.Meta=" + \
    "") + "'"

COMPAT_DIR := "temp/compat"
VM_COMPAT_OUTPUT_DIR := "bin/vm-compat-output"

# Build all op-program binaries
op-program: op-program-host op-program-client op-program-client-mips

# Build op-program host binary
op-program-host: (go_build "./bin/op-program" "./host/cmd/main.go" "-ldflags" _HOST_LDFLAGS)

# Build op-program client binaries (client + interop)
op-program-client:
    env GO111MODULE=on GOOS={{TARGETOS}} GOARCH={{TARGETARCH}} go build -v -ldflags {{_CLIENT_LDFLAGS}} -o ./bin/op-program-client ./client/cmd/main.go
    env GO111MODULE=on GOOS={{TARGETOS}} GOARCH={{TARGETARCH}} go build -v -ldflags {{_CLIENT_LDFLAGS}} -o ./bin/op-program-client-interop ./client/interopcmd/main.go

# Build MIPS client binaries
op-program-client-mips: op-program-client-mips64 op-program-client-mips64-interop

# Build MIPS64 client binary
op-program-client-mips64:
    env GO111MODULE=on GOOS=linux GOARCH=mips64 GOMIPS64=softfloat go build -v -ldflags {{_CLIENT_LDFLAGS}} -o ./bin/op-program-client64.elf ./client/cmd/main.go

# Build MIPS64 interop client binary
op-program-client-mips64-interop:
    env GO111MODULE=on GOOS=linux GOARCH=mips64 GOMIPS64=softfloat go build -v -ldflags {{_CLIENT_LDFLAGS}} -o ./bin/op-program-client-interop.elf ./client/interopcmd/main.go

# Build RISC-V client binary
op-program-client-riscv:
    env GO111MODULE=on GOOS=linux GOARCH=riscv64 go build -v -gcflags="all=-d=softfloat" -ldflags {{_CLIENT_LDFLAGS}} -o ./bin/op-program-client-riscv.elf ./client/cmd/main.go

# Check custom chain configurations
check-custom-chains: op-program-host
    ./bin/op-program configs check-custom-chains

# Build reproducible prestates via Docker
build-reproducible-prestate: check-custom-chains
    docker build --build-arg GO_VERSION=1.24.2-alpine3.21 --build-arg EXPORT_TARGET=next  --output ./bin/ --progress plain -f Dockerfile.repro ../
    docker build --build-arg GO_VERSION=1.24.2-alpine3.21 --build-arg EXPORT_TARGET=current --output ./bin/ --progress plain -f Dockerfile.repro ../

# Print prestate hashes
output-prestate-hash:
    @echo "-------------------- op-program Production Prestates --------------------"
    @printf "\nCannon64 Absolute prestate hash: \n"
    @cat ./bin/prestate-proof-mt64.json | jq -r .pre
    @echo "-------------------- op-program Experimental Prestates --------------------"
    @printf "\nCannon64Next Absolute prestate hash: \n"
    @cat ./bin/prestate-proof-mt64Next.json | jq -r .pre
    @printf "\nCannonInterop Absolute prestate hash: \n"
    @cat ./bin/prestate-proof-interop.json | jq -r .pre
    @printf "\nCannonInteropNext Absolute prestate hash: \n"
    @cat ./bin/prestate-proof-interopNext.json | jq -r .pre
    @echo

# Build reproducible prestates and print hashes
reproducible-prestate: build-reproducible-prestate output-prestate-hash

# Verify reproducibility of prestates
verify-reproducibility:
    rm -rf temp/states
    ./scripts/build-prestates.sh
    env GO111MODULE=on go run ./prestates/verify/verify.go --input temp/states/versions.json

# Clean build artifacts
clean:
    rm -rf bin "{{COMPAT_DIR}}"

# Run tests
test: (go_test "./...")

# Capture mainnet genesis test data
capture-mainnet-genesis: op-program-host op-program-client
    rm -rf "{{COMPAT_DIR}}/mainnet-genesis" "{{COMPAT_DIR}}/mainnet-genesis.tar.bz"
    env GO111MODULE=on go run ./verify/mainnet/cmd/mainnet.go --l1 $MAINNET_L1URL --l1.beacon $MAINNET_BEACON_URL --l2 $MAINNET_L2URL --datadir "{{COMPAT_DIR}}/mainnet-genesis" --l1.head "0x4903424f6cc2cfba7c2bf8c8f48ca46721c963fa64b411cfee3697b781e3e5f1" --l2.start "105235063" --l2.end "105235064"
    tar jcf "{{COMPAT_DIR}}/mainnet-genesis.tar.bz" -C "{{COMPAT_DIR}}" mainnet-genesis

# Capture sepolia delta test data
capture-sepolia-delta: op-program-host op-program-client
    rm -rf "{{COMPAT_DIR}}/sepolia-delta" "{{COMPAT_DIR}}/sepolia-delta.tar.bz"
    env GO111MODULE=on go run ./verify/sepolia/cmd/sepolia.go --l1 $SEPOLIA_L1URL --l1.beacon $SEPOLIA_BEACON_URL --l2 $SEPOLIA_L2URL --datadir "{{COMPAT_DIR}}/sepolia-delta" --l1.head "0x935428728bcfcfeb2e5ba9175fd2890e52831dae221aa4d5dcffed8320edc001" --l2.start "8728200" --l2.end "8728320"
    tar jcf "{{COMPAT_DIR}}/sepolia-delta.tar.bz" -C "{{COMPAT_DIR}}" sepolia-delta

# Capture sepolia ecotone test data
capture-sepolia-ecotone: op-program-host op-program-client
    rm -rf "{{COMPAT_DIR}}/sepolia-ecotone" "{{COMPAT_DIR}}/sepolia-ecotone.tar.bz"
    env GO111MODULE=on go run ./verify/sepolia/cmd/sepolia.go --l1 $SEPOLIA_L1URL --l1.beacon $SEPOLIA_BEACON_URL --l2 $SEPOLIA_L2URL --datadir "{{COMPAT_DIR}}/sepolia-ecotone" --l1.head "0x5d491a8c1e728a4e70720c09fefdaa083681a9421cd365af85220cf8bd4448a3" --l2.start "9205715" --l2.end "9205815"
    tar jcf "{{COMPAT_DIR}}/sepolia-ecotone.tar.bz" -C "{{COMPAT_DIR}}" sepolia-ecotone

# Capture sepolia fjord test data
capture-sepolia-fjord: op-program-host op-program-client
    rm -rf "{{COMPAT_DIR}}/sepolia-fjord" "{{COMPAT_DIR}}/sepolia-fjord.tar.bz"
    env GO111MODULE=on go run ./verify/sepolia/cmd/sepolia.go --l1 $SEPOLIA_L1URL --l1.beacon $SEPOLIA_BEACON_URL --l2 $SEPOLIA_L2URL --datadir "{{COMPAT_DIR}}/sepolia-fjord" --l1.head "0x93ba31bf89e54237af6e6564e69d328b2b5202adf643de4cb097431f74f4a6c1" --l2.start "15378256" --l2.end "15378356"
    tar jcf "{{COMPAT_DIR}}/sepolia-fjord.tar.bz" -C "{{COMPAT_DIR}}" sepolia-fjord

# Capture sepolia granite test data
capture-sepolia-granite: op-program-host op-program-client
    rm -rf "{{COMPAT_DIR}}/sepolia-granite" "{{COMPAT_DIR}}/sepolia-granite.tar.bz"
    env GO111MODULE=on go run ./verify/sepolia/cmd/sepolia.go --l1 $SEPOLIA_L1URL --l1.beacon $SEPOLIA_BEACON_URL --l2 $SEPOLIA_L2URL --datadir "{{COMPAT_DIR}}/sepolia-granite" --l1.head "0x4a4e2b07b1cb468f20b37de54308ec70d2a96453e5186b0bf0929bd5b63ca492" --l2.start "15837930" --l2.end "15838030"
    tar jcf "{{COMPAT_DIR}}/sepolia-granite.tar.bz" -C "{{COMPAT_DIR}}" sepolia-granite

# Capture sepolia holocene test data
capture-sepolia-holocene: op-program-host op-program-client
    rm -rf "{{COMPAT_DIR}}/sepolia-holocene" "{{COMPAT_DIR}}/sepolia-holocene.tar.bz"
    env GO111MODULE=on go run ./verify/sepolia/cmd/sepolia.go --l1 $SEPOLIA_L1URL --l1.beacon $SEPOLIA_BEACON_URL --l2 $SEPOLIA_L2URL --datadir "{{COMPAT_DIR}}/sepolia-holocene" --l1.head "0x0fd505af2e97a0cf59232a8615340689ee4dc14d022103f6342ba4fd6b89f066" --l2.start "20415330" --l2.end "20415430"
    tar jcf "{{COMPAT_DIR}}/sepolia-holocene.tar.bz" -C "{{COMPAT_DIR}}" sepolia-holocene

# Capture sepolia isthmus test data
capture-sepolia-isthmus: op-program-host op-program-client
    rm -rf "{{COMPAT_DIR}}/sepolia-isthmus" "{{COMPAT_DIR}}/sepolia-isthmus.tar.bz"
    env GO111MODULE=on go run ./verify/sepolia/cmd/sepolia.go --l1 $SEPOLIA_L1URL --l1.beacon $SEPOLIA_BEACON_URL --l2 $SEPOLIA_L2URL --datadir "{{COMPAT_DIR}}/sepolia-isthmus" --l1.head "0x6ae443d11c3896a458f80905601920f16e6ae6cb34f070db7307195f6e23e58c" --l2.start "26551530" --l2.end "26551630"
    tar jcf "{{COMPAT_DIR}}/sepolia-isthmus.tar.bz" -C "{{COMPAT_DIR}}" sepolia-isthmus

# Capture all chain test data
capture-chain-test-data: capture-mainnet-genesis capture-sepolia-delta capture-sepolia-ecotone capture-sepolia-fjord capture-sepolia-granite capture-sepolia-holocene capture-sepolia-isthmus

# Verify mainnet genesis compatibility
verify-mainnet-genesis: op-program-host op-program-client
    ./scripts/run-compat.sh "mainnet-genesis"

# Verify sepolia delta compatibility
verify-sepolia-delta: op-program-host op-program-client
    ./scripts/run-compat.sh "sepolia-delta"

# Verify sepolia ecotone compatibility
verify-sepolia-ecotone: op-program-host op-program-client
    ./scripts/run-compat.sh "sepolia-ecotone"

# Verify sepolia fjord compatibility
verify-sepolia-fjord: op-program-host op-program-client
    ./scripts/run-compat.sh "sepolia-fjord"

# Verify sepolia granite compatibility
verify-sepolia-granite: op-program-host op-program-client
    ./scripts/run-compat.sh "sepolia-granite"

# Verify sepolia holocene compatibility
verify-sepolia-holocene: op-program-host op-program-client
    ./scripts/run-compat.sh "sepolia-holocene"

# Verify sepolia isthmus compatibility
verify-sepolia-isthmus: op-program-host op-program-client
    ./scripts/run-compat.sh "sepolia-isthmus"

# Verify all compatibility tests
verify-compat: verify-mainnet-genesis verify-sepolia-delta verify-sepolia-ecotone verify-sepolia-fjord verify-sepolia-granite verify-sepolia-holocene verify-sepolia-isthmus

# Analyze current op-program client for VM compatibility
analyze-op-program-client-current:
    ./scripts/run-static-analysis.sh ./vm-profiles/cannon-multithreaded-64.yaml ./compatibility-test/baseline-cannon-multithreaded-64.json

# Analyze next op-program client for VM compatibility
analyze-op-program-client-next:
    ./scripts/run-static-analysis.sh ./vm-profiles/cannon-multithreaded-64-next.yaml ./compatibility-test/baseline-cannon-multithreaded-64-next.json

# Run VM compatibility tests
run-vm-compat:
    @rm -rf "{{VM_COMPAT_OUTPUT_DIR}}" && mkdir -p "{{VM_COMPAT_OUTPUT_DIR}}"
    @docker build \
        --build-arg GO_VERSION=1.24.10-alpine3.21 \
        --build-arg VM_TARGET=current \
        --progress plain \
        --output "{{VM_COMPAT_OUTPUT_DIR}}" \
        -f Dockerfile.vmcompat ../
    @exit $(cat "{{VM_COMPAT_OUTPUT_DIR}}/vm-compat-exit-code")
    # TODO(#18334): Uncomment once vm-compat supports go1.25
    #@docker build --build-arg GO_VERSION=1.25.4-alpine3.21 --build-arg VM_TARGET=next --progress plain --output "{{VM_COMPAT_OUTPUT_DIR}}" -f Dockerfile.vmcompat ../
    #@exit $(cat "{{VM_COMPAT_OUTPUT_DIR}}/vm-compat-exit-code")