FastLED Light Example

Author: sivar2311

examples/Light/Light_FastLED_WS2812.ino

@@ -0,0 +1,128 @@
+/*
+ * If you encounter any issues:
+ * - check the readme.md at https://github.com/sinricpro/esp8266-esp32-sdk/blob/master/README.md
+ * - ensure all dependent libraries are installed
+ *   - see https://github.com/sinricpro/esp8266-esp32-sdk/blob/master/README.md#arduinoide
+ *   - see https://github.com/sinricpro/esp8266-esp32-sdk/blob/master/README.md#dependencies
+ * - open serial monitor and check whats happening
+ * - check full user documentation at https://sinricpro.github.io/esp8266-esp32-sdk
+ * - visit https://github.com/sinricpro/esp8266-esp32-sdk/issues and check for existing issues or open a new one
+ */
+
+// Uncomment the following line to enable serial debug output
+//#define ENABLE_DEBUG
+
+#ifdef ENABLE_DEBUG
+       #define DEBUG_ESP_PORT Serial
+       #define NODEBUG_WEBSOCKETS
+       #define NDEBUG
+#endif 
+
+#include <Arduino.h>
+#ifdef ESP8266 
+       #include <ESP8266WiFi.h>
+#endif 
+#ifdef ESP32   
+       #include <WiFi.h>
+#endif
+
+#define FASTLED_ESP8266_DMA
+#define FASTLED_ESP8266_RAW_PIN_ORDER
+#include <FastLED.h>
+
+#include "SinricPro.h"
+#include "SinricProLight.h"
+
+#define WIFI_SSID         "YOUR-WIFI-SSID"    
+#define WIFI_PASS         "YOUR-WIFI-PASSWORD"
+#define APP_KEY           "YOUR-APP-KEY"      // Should look like "de0bxxxx-1x3x-4x3x-ax2x-5dabxxxxxxxx"
+#define APP_SECRET        "YOUR-APP-SECRET"   // Should look like "5f36xxxx-x3x7-4x3x-xexe-e86724a9xxxx-4c4axxxx-3x3x-x5xe-x9x3-333d65xxxxxx"
+#define LIGHT_ID          "YOUR-DEVICE-ID"    // Should look like "5dc1564130xxxxxxxxxxxxxx"
+#define BAUD_RATE         9600                // Change baudrate to your need
+
+#define NUM_LEDS          1                   // how much LEDs are on the stripe
+#define LED_PIN           3                   // LED stripe is connected to PIN 3
+
+bool powerState;        
+int globalBrightness = 100;
+CRGB leds[NUM_LEDS];
+
+bool onPowerState(const String &deviceId, bool &state) {
+  powerState = state;
+  if (state) {
+    FastLED.setBrightness(map(globalBrightness, 0, 100, 0, 255));
+  } else {
+    FastLED.setBrightness(0);
+  }
+  FastLED.show();
+  return true; // request handled properly
+}
+
+bool onBrightness(const String &deviceId, int &brightness) {
+  globalBrightness = brightness;
+  FastLED.setBrightness(map(brightness, 0, 100, 0, 255));
+  FastLED.show();
+  return true;
+}
+
+bool onAdjustBrightness(const String &deviceId, int brightnessDelta) {
+  globalBrightness += brightnessDelta;
+  brightnessDelta = globalBrightness;
+  FastLED.setBrightness(map(globalBrightness, 0, 100, 0, 255));
+  FastLED.show();
+  return true;
+}
+
+bool onColor(const String &deviceId, byte &r, byte &g, byte &b) {
+  fill_solid(leds, NUM_LEDS, CRGB(r, g, b));
+  FastLED.show();
+  return true;
+}
+
+void setupFastLED() {
+  FastLED.addLeds<WS2812B, LED_PIN, RGB>(leds, NUM_LEDS);
+  FastLED.setBrightness(map(globalBrightness, 0, 100, 0, 255));
+  fill_solid(leds, NUM_LEDS, CRGB::White);
+  FastLED.show();
+}
+
+void setupWiFi() {
+  Serial.printf("\r\n[Wifi]: Connecting");
+  WiFi.begin(WIFI_SSID, WIFI_PASS);
+
+  while (WiFi.status() != WL_CONNECTED) {
+    Serial.printf(".");
+    delay(250);
+  }
+  IPAddress localIP = WiFi.localIP();
+  Serial.printf("connected!\r\n[WiFi]: IP-Address is %s\r\n", localIP.toString().c_str());
+}
+
+void setupSinricPro() {
+  // get a new Light device from SinricPro
+  SinricProLight &myLight = SinricPro[LIGHT_ID];
+
+  // set callback function to device
+  myLight.onPowerState(onPowerState);
+  myLight.onBrightness(onBrightness);
+  myLight.onAdjustBrightness(onAdjustBrightness);
+  myLight.onColor(onColor);
+
+  // setup SinricPro
+  SinricPro.onConnected([](){ Serial.printf("Connected to SinricPro\r\n"); }); 
+  SinricPro.onDisconnected([](){ Serial.printf("Disconnected from SinricPro\r\n"); });
+  SinricPro.restoreDeviceStates(true);
+  SinricPro.begin(APP_KEY, APP_SECRET);
+}
+
+// main setup function
+void setup() {
+  Serial.begin(BAUD_RATE); Serial.printf("\r\n\r\n");
+  setupFastLED();
+  setupWiFi();
+  setupSinricPro();
+}
+
+void loop() {
+  SinricPro.handle();
+}