FormArith/flake.nix at main · timmykill/FormArith · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
{
  inputs = {
    nixpkgs.url = "nixpkgs/nixos-24.05";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      self,
      flake-utils,
      nixpkgs,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs { inherit system; };
        coqPackages = pkgs.coqPackages_8_19;
      in
      rec {
        packages = {
          theories = let
            autosubst = coqPackages.mkCoqDerivation {
              pname = "autosubst";
              version = "1.9";

              # The tarball is not present in the release
              src = pkgs.fetchFromGitHub {
                owner = "coq-community";
                repo = "autosubst";
                rev = "v1.9";
                sha256 = "sha256-XiLZjMc+1iwRGOstfLm/WQRF6FTdX6oJr5urn3wmLlA=";
              };
            };
          in coqPackages.mkCoqDerivation rec {
            pname = "FormArith";
            opam-name = "FormArith";
            version = "0.1.0";

            src = ./.;
            useDune = true;

            propagatedBuildInputs = [ autosubst ];
          };

          default = packages.theories;
        };

        devShells.default = pkgs.mkShell {
          inputsFrom = with packages; [ theories ];
          packages = with coqPackages; [ vscoq-language-server ];
        };

        formatter = pkgs.nixfmt-rfc-style;
      }
    );
}