Add flake.nix

.gitignore

@@ -1,6 +1,6 @@
+/result
 /target
 *.csv
-*.png
 *.data
 *.old
 *.log

README.md

@@ -205,4 +205,8 @@ The help message can be shown with `udperf --help`.
 ## System Design
 The most important components of udperf are shown in the following component diagram.
 
-![udperf Component Diagram](doc/figures/udperf-component.svg)
+![udperf Component Diagram](doc/figures/udperf-component.svg)
+
+## Run with nix
+
+`nix run github:PickingUpPieces/udperf -- [OPTIONS] [MODE]`

flake.nix

@@ -0,0 +1,62 @@
+{
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+    flake-utils.url = "github:numtide/flake-utils";
+  };
+  outputs =
+    {
+      self,
+      nixpkgs,
+      flake-utils,
+    }:
+    flake-utils.lib.eachDefaultSystem (
+      system:
+      let
+        pkgs = import nixpkgs {
+          inherit system;
+        };
+        manifest = (pkgs.lib.importTOML ./Cargo.toml).package;
+        rust-toolchain = pkgs.symlinkJoin {
+          name = "rust-toolchain";
+          paths = with pkgs; [
+            rustc
+            cargo
+            rustPlatform.rustcSrc
+          ];
+        };
+      in
+      {
+        packages.default = pkgs.rustPlatform.buildRustPackage rec {
+          pname = manifest.name;
+          version = manifest.version;
+          cargoLock = {
+            lockFile = ./Cargo.lock;
+            outputHashes = {
+              # explicit hashes required for cargo git dependencies
+              "csv-1.1.5" = "sha256-IGfThZankbhI2LsQzJ0TdLhrw3fNlEB2P5pidvPUIxg=";
+              "io-uring-0.6.3" = "sha256-dAlKSPniUAJdme9HvTg/lr9Zqkl1yOC7xIGoAanl4z8=";
+            };
+          };
+          src = pkgs.lib.cleanSource ./.;
+          nativeBuildInputs = with pkgs; [
+            pkg-config
+          ];
+          buildInputs = with pkgs; [
+            hwloc
+          ];
+          doCheck = false; # do not run tests
+        };
+        devShells.default = pkgs.mkShell {
+          buildInputs = with pkgs; [
+            clippy
+            rustfmt
+            rust-analyzer
+            rust-toolchain
+            pkg-config
+            hwloc
+          ];
+          RUST_SRC_PATH = "${pkgs.rustPlatform.rustLibSrc}";
+        };
+      }
+    );
+}