✨ [Artifact 1314] トパーズのブローチを作成

Asset/data/asset/functions/artifact/1314.topaz_broach/give/1.trigger.mcfunction

@@ -0,0 +1,7 @@
+#> asset:artifact/1314.topaz_broach/give/1.trigger
+#
+# 神器の取得処理の呼び出し時に実行されるfunction
+#
+# @within tag/function asset:artifact/give
+
+execute if data storage asset:context {id:1314} run function asset:artifact/1314.topaz_broach/give/2.give

Asset/data/asset/functions/artifact/1314.topaz_broach/give/2.give.mcfunction

@@ -0,0 +1,73 @@
+#> asset:artifact/1314.topaz_broach/give/2.give
+#
+# 神器の作成部 ここでID等を定義する
+#
+# @user
+# @within function asset:artifact/1314.topaz_broach/give/1.trigger
+
+# 神器の説明や消費MPなどをここで設定する。
+# 最後にasset:artifact/common/giveを実行することで入手可能。
+
+# 神器のID (int) スプレッドシートの値を入れる
+    data modify storage asset:artifact ID set value 1314
+# 神器のベースアイテム
+    data modify storage asset:artifact Item set value "minecraft:stick"
+# 神器の名前 (TextComponentString)
+    data modify storage asset:artifact Name set value '{"text":"トパーズのブローチ","color":"gold"}'
+# 神器の説明文 (TextComponentString[])
+    data modify storage asset:artifact Lore set value ['{"text":"バリアを4得る","color":"white"}','{"text":"このバリアは最大20まで蓄積する","color":"white"}']
+# 消費アイテム ({Item: TextComponent, Count: int, Extra?: TextComponent}) (オプション)
+    # data modify storage asset:artifact ConsumeItem.Item set value '{"translate":"item.minecraft.stick"}'
+    # data modify storage asset:artifact ConsumeItem.Count set value 1
+    # data modify storage asset:artifact ConsumeItem.Extra set value
+# 使用回数 (int) (オプション)
+    # data modify storage asset:artifact RemainingCount set value
+# 神器を発動できるスロット (string) Wikiを参照
+    data modify storage asset:artifact Slot set value "hotbar"
+# 神器のトリガー (string) Wikiを参照
+    data modify storage asset:artifact Trigger set value "onKilled"
+# 効果が重複可能か否か (boolean) (オプション)
+    # data modify storage asset:artifact EnableDuplication set value
+# 神器の発動条件 (TextComponentString) (オプション)
+    # data modify storage asset:artifact Condition set value
+# 攻撃に関する情報 -Damage量 (literal[]/literal) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.Damage set value [0,0]
+# 攻撃に関する情報 -攻撃タイプ (string[]) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.AttackType set value [Physical,Magic]
+# 攻撃に関する情報 -攻撃属性 (string[]) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.ElementType set value [Fire,Water,Thunder,None]
+# 攻撃に関する情報 -防御無視 (boolean) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.BypassResist set value
+# 攻撃に関する情報 -範囲攻撃 (string) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.IsRangeAttack set value
+# 攻撃に関する情報 -攻撃範囲 (literal) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.AttackRange set value
+# MP消費量 (int)
+    data modify storage asset:artifact MPCost set value 10
+# MP必要量 (int) (オプション)
+    # data modify storage asset:artifact MPRequire set value
+# MP回復量 (int)
+    # data modify storage asset:artifact MPHealWhenHit set value
+# 神器のクールダウン (int) (オプション)
+    data modify storage asset:artifact LocalCooldown set value 10
+# 種別クールダウン ({Type: string, Duration: int}) (オプション)
+    # data modify storage asset:artifact TypeCooldown.Type set value
+    # data modify storage asset:artifact TypeCooldown.Duration set value
+# 第二種別クールダウン ({Type: string, Duration: int}) (オプション)
+    # data modify storage asset:artifact SecondaryTypeCooldown.Type set value
+    # data modify storage asset:artifact SecondaryTypeCooldown.Duration set value
+# グローバルクールダウン (int) (オプション)
+    # data modify storage asset:artifact SpecialCooldown set value
+# クールダウンによる使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    data modify storage asset:artifact DisableCooldownMessage set value true
+# MP不足による使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    data modify storage asset:artifact DisableMPMessage set value true
+# 破壊時の音を鳴らさないかどうか (boolean) (オプション)
+    # data modify storage asset:artifact DisableBreakSound set value
+# 扱える神 (string[]) Wikiを参照
+    data modify storage asset:artifact CanUsedGod set value ["Flora", "Urban", "Nyaptov", "Wi-ki", "Rumor"]
+# カスタムNBT (NBTCompound) 追加で指定したいNBT (オプション)
+    # data modify storage asset:artifact CustomNBT set value {}
+
+# 神器の入手用function
+    function asset:artifact/common/give

Asset/data/asset/functions/artifact/1314.topaz_broach/register.mcfunction

@@ -0,0 +1,8 @@
+#> asset:artifact/1314.topaz_broach/register
+#
+# 神器プールへの登録処理
+#
+# @within tag/function asset:artifact/register
+
+data modify storage asset:artifact RarityRegistry[2] append value [1314]
+data modify storage asset:artifact RarityRegistryWithColor.Green[2] append value [1314]

Asset/data/asset/functions/artifact/1314.topaz_broach/trigger/1.trigger.mcfunction

@@ -0,0 +1,8 @@
+#> asset:artifact/1314.topaz_broach/trigger/1.trigger
+#
+# 指定したイベントタイミングで実行されるfunction
+#
+# @within tag/function asset:artifact/**
+
+# storage asset:idの%slot%に装備している神器のIDが入っているので比較し、~/2.check_condition.mcfunctionを実行する
+    execute if data storage asset:context id{hotbar:[1314]} run function asset:artifact/1314.topaz_broach/trigger/2.check_condition

Asset/data/asset/functions/artifact/1314.topaz_broach/trigger/2.check_condition.mcfunction

@@ -0,0 +1,19 @@
+#> asset:artifact/1314.topaz_broach/trigger/2.check_condition
+#
+# 神器の発動条件をチェックします
+#
+# @within function asset:artifact/1314.topaz_broach/trigger/1.trigger
+
+# ID指定する
+    data modify storage asset:artifact TargetID set value 1314
+# 神器の基本的な条件の確認を行うfunction、成功している場合CanUsedタグが付く
+    function asset:artifact/common/check_condition/hotbar
+# 他にアイテム等確認する場合はここに書く
+
+# 既にバリアがあるなら、バリアが最大値かチェックし、最大値ならCanUsedを削除
+    execute if entity @s[tag=CanUsed] run data modify storage api: Argument.ID set value 345
+    execute if entity @s[tag=CanUsed] run function api:entity/mob/effect/get/from_id
+    execute if entity @s[tag=CanUsed] if data storage api: Return.Effect run function asset:artifact/1314.topaz_broach/trigger/2.check_condition/barrier_is_max
+
+# CanUsedタグをチェックして3.main.mcfunctionを実行する
+    execute if entity @s[tag=CanUsed] run function asset:artifact/1314.topaz_broach/trigger/3.main

Asset/data/asset/functions/artifact/1314.topaz_broach/trigger/2.check_condition/barrier_is_max.mcfunction

@@ -0,0 +1,21 @@
+#> asset:artifact/1314.topaz_broach/trigger/2.check_condition/barrier_is_max
+#
+# バリアが最大値か？
+#
+# @within function asset:artifact/1314.topaz_broach/trigger/2.check_condition
+
+#> Private
+# @private
+    #declare score_holder $MaxBarrier
+    #declare score_holder $CurrentBarrier
+
+# 計算に必要な値を取得
+    execute store result score $MaxBarrier Temporary run data get storage api: Return.Effect.Field.MaxBarrier
+    execute store result score $CurrentBarrier Temporary run data get storage api: Return.Effect.Field.Barrier
+
+# バリア最大値 = 現在のバリアならCanUsedを削除
+    execute if score $MaxBarrier Temporary = $CurrentBarrier Temporary run tag @s remove CanUsed
+
+# リセット
+    scoreboard players reset $MaxBarrier Temporary
+    scoreboard players reset $CurrentBarrier Temporary

Asset/data/asset/functions/artifact/1314.topaz_broach/trigger/3.main.mcfunction

@@ -0,0 +1,21 @@
+#> asset:artifact/1314.topaz_broach/trigger/3.main
+#
+# 神器のメイン処理部
+#
+# @within function asset:artifact/1314.topaz_broach/trigger/2.check_condition
+
+# 基本的な使用時の処理(MP消費や使用回数の処理など)を行う
+    function asset:artifact/common/use/hotbar
+
+# ここから先は神器側の効果の処理を書く
+
+# 演出
+    particle minecraft:wax_on ~ ~1.2 ~ 1 0.4 1 0.2 20
+
+# バリア付与
+    data modify storage api: Argument.ID set value 345
+    data modify storage api: Argument.Duration set value 400
+    data modify storage api: Argument.FieldOverride.Barrier set value 4
+    data modify storage api: Argument.FieldOverride.MaxBarrier set value 20
+    function api:entity/mob/effect/give
+    function api:entity/mob/effect/reset

Asset/data/asset/functions/effect/0345.topaz_protection/_/end.mcfunction

@@ -0,0 +1,7 @@
+#> asset:effect/0345.topaz_protection/_/end
+#
+# Effectの効果の終了時に実行されるfunction
+#
+# @within tag/function asset:effect/end
+
+execute if data storage asset:context {id:345} run function asset:effect/0345.topaz_protection/end/

Asset/data/asset/functions/effect/0345.topaz_protection/_/given.mcfunction

@@ -0,0 +1,7 @@
+#> asset:effect/0345.topaz_protection/_/given
+#
+# Effectが付与された時に実行されるfunction
+#
+# @within tag/function asset:effect/given
+
+execute if data storage asset:context {id:345} run function asset:effect/0345.topaz_protection/given/

Asset/data/asset/functions/effect/0345.topaz_protection/_/re-given.mcfunction

@@ -0,0 +1,7 @@
+#> asset:effect/0345.topaz_protection/_/re-given
+#
+# Effectが上書きされた時に実行されるfunction
+#
+# @within tag/function asset:effect/re-given
+
+execute if data storage asset:context {id:345} run function asset:effect/0345.topaz_protection/re-given/

Asset/data/asset/functions/effect/0345.topaz_protection/_/register.mcfunction

@@ -0,0 +1,7 @@
+#> asset:effect/0345.topaz_protection/_/register
+#
+#
+#
+# @within tag/function asset:effect/register
+
+execute if data storage asset:context {id:345} run function asset:effect/0345.topaz_protection/register

Asset/data/asset/functions/effect/0345.topaz_protection/_/remove.mcfunction

@@ -0,0 +1,7 @@
+#> asset:effect/0345.topaz_protection/_/remove
+#
+# Effectが神器や牛乳によって削除された時に実行されるfunction
+#
+# @within tag/function asset:effect/remove
+
+execute if data storage asset:context {id:345} run function asset:effect/0345.topaz_protection/remove/

Asset/data/asset/functions/effect/0345.topaz_protection/barrier/add.mcfunction

@@ -0,0 +1,14 @@
+#> asset:effect/0345.topaz_protection/barrier/add
+#
+#
+#
+# @within function
+#   asset:effect/0345.topaz_protection/given/
+#   asset:effect/0345.topaz_protection/re-given/
+
+# バリア設定
+    data modify storage api: Argument.Amount set from storage asset:context this.Barrier
+    data modify storage api: Argument.UUID set from storage asset:context this.UUID
+    data modify storage api: Argument.Priority set value 1
+    data modify storage api: Argument.WipedCallback set value "asset:effect/0345.topaz_protection/barrier/break"
+    function api:entity/player/absorption/add

Asset/data/asset/functions/effect/0345.topaz_protection/barrier/break.mcfunction

@@ -0,0 +1,10 @@
+#> asset:effect/0345.topaz_protection/barrier/break
+#
+#
+#
+# @within function asset:effect/0345.topaz_protection/barrier/add
+
+# このエフェクトを解除
+    data modify storage api: Argument.ID set value 345
+    function api:entity/mob/effect/remove/from_id
+    function api:entity/mob/effect/reset

Asset/data/asset/functions/effect/0345.topaz_protection/barrier/remove.mcfunction

@@ -0,0 +1,12 @@
+#> asset:effect/0345.topaz_protection/barrier/remove
+#
+#
+#
+# @within function
+#   asset:effect/0345.topaz_protection/end/
+#   asset:effect/0345.topaz_protection/re-given/
+#   asset:effect/0345.topaz_protection/remove/
+
+# バリア削除
+    data modify storage api: Argument.UUID set from storage asset:context this.UUID
+    function api:entity/player/absorption/remove

Asset/data/asset/functions/effect/0345.topaz_protection/end/.mcfunction

@@ -0,0 +1,8 @@
+#> asset:effect/0345.topaz_protection/end/
+#
+# Effectの効果が切れた時の処理
+#
+# @within function asset:effect/0345.topaz_protection/_/end
+
+# バリア削除
+    function asset:effect/0345.topaz_protection/barrier/remove

Asset/data/asset/functions/effect/0345.topaz_protection/given/.mcfunction

@@ -0,0 +1,8 @@
+#> asset:effect/0345.topaz_protection/given/
+#
+# Effectが付与された時の処理
+#
+# @within function asset:effect/0345.topaz_protection/_/given
+
+# バリア付与
+    function asset:effect/0345.topaz_protection/barrier/add

Asset/data/asset/functions/effect/0345.topaz_protection/re-given/.mcfunction

@@ -0,0 +1,35 @@
+#> asset:effect/0345.topaz_protection/re-given/
+#
+# Effectが上書きされた時の処理
+#
+# @within function asset:effect/0345.topaz_protection/_/re-given
+
+#> Private
+# @private
+    #declare score_holder $MaxBarrier
+    #declare score_holder $CurrentBarrier
+    #declare score_holder $Add
+
+# バリア量取得
+    data modify storage api: Argument.UUID set from storage asset:context this.UUID
+    function api:entity/player/absorption/get
+
+# 各値取得
+    execute store result score $MaxBarrier Temporary run data get storage asset:context this.MaxBarrier 10
+    execute store result score $CurrentBarrier Temporary run data get storage api: Return.Absorption.Amount 10
+    execute store result score $Add Temporary run data get storage asset:context this.Barrier 10
+
+    #tellraw @a {"storage":"api:","nbt":"Return.Absorption"}
+
+# 計算してフィールドに入れておく
+    scoreboard players operation $CurrentBarrier Temporary += $Add Temporary
+    execute store result storage asset:context this.Barrier float 0.1 run scoreboard players operation $CurrentBarrier Temporary < $MaxBarrier Temporary
+
+# リセット
+    scoreboard players reset $MaxBarrier Temporary
+    scoreboard players reset $CurrentBarrier Temporary
+    scoreboard players reset $Add Temporary
+
+# バリアを更新
+    function asset:effect/0345.topaz_protection/barrier/remove
+    function asset:effect/0345.topaz_protection/barrier/add

Asset/data/asset/functions/effect/0345.topaz_protection/register.mcfunction

@@ -0,0 +1,39 @@
+#> asset:effect/0345.topaz_protection/register
+#
+# Effectのデータを指定
+#
+# @within function asset:effect/0345.topaz_protection/_/register
+
+# ExtendsSafe (boolean) (default = false)
+    # data modify storage asset:effect ExtendsSafe set value true
+# ID (int)
+    data modify storage asset:effect ID set value 345
+# 名前 (TextComponentString)
+    data modify storage asset:effect Name set value '{"text":"トパーズの護り","color":"gold"}'
+# 説明文 (TextComponentString[])
+    data modify storage asset:effect Description set value ['{"text":"蓄積するバリアを得る","color":"white"}']
+# 効果時間 (int) (default = API || error)
+    # data modify storage asset:effect Duration set value
+# スタック (int) (default = API || 1)
+    # data modify storage asset:effect Stack set value
+# 効果時間の操作方法 (default = API || "replace")
+    # data modify storage asset:effect DurationOperation set value
+# スタックの操作方法 (default = API || "replace")
+    # data modify storage asset:effect StackOperation set value
+# 最大効果時間 (int) (default = 2147483647)
+    # data modify storage asset:effect MaxDuration set value
+# 最大スタック (int) (default = 2147483647)
+    data modify storage asset:effect MaxStack set value 1
+# 悪い効果か否か (boolean)
+    data modify storage asset:effect IsBadEffect set value false
+# 死亡時のエフェクトの処理 (default = "remove")
+    # data modify storage asset:effect ProcessOnDied set value
+# 消すのに必要なレベル (int) (default = 1)
+    data modify storage asset:effect RequireClearLv set value 3
+# エフェクトをUIに表示するか (boolean) (default = true)
+    # data modify storage asset:effect Visible set value
+# エフェクトのスタックををUIに表示するか (boolean) (default = true)
+    data modify storage asset:effect StackVisible set value false
+
+# フィールド
+    data modify storage asset:effect Field.UUID set value [I;1,3,345,0]

Asset/data/asset/functions/effect/0345.topaz_protection/remove/.mcfunction

@@ -0,0 +1,8 @@
+#> asset:effect/0345.topaz_protection/remove/
+#
+# Effectが削除された時の処理
+#
+# @within function asset:effect/0345.topaz_protection/_/remove
+
+# バリア削除
+    function asset:effect/0345.topaz_protection/barrier/remove

Asset/data/asset/tags/functions/artifact/give.json

@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:artifact/1314.topaz_broach/give/1.trigger",
         "asset:artifact/1140.over_pulse_booster/give/1.trigger",
         "asset:artifact/1139.over_pulse_legframe/give/1.trigger",
         "asset:artifact/1138.over_pulse_bodyarmor/give/1.trigger",
@@ -517,4 +518,4 @@
         "asset:artifact/0735.collision_plate/give/1.trigger",
         "asset:artifact/0745.blade_of_whirlwind/give/1.trigger"
     ]
-}
+}

Asset/data/asset/tags/functions/artifact/killed.json

@@ -1,9 +1,10 @@
 {
     "values": [
+        "asset:artifact/1314.topaz_broach/trigger/1.trigger",
         "asset:artifact/0292.craving_sword/kill/1.trigger",
         "asset:artifact/0728.magatama_of_soul_eating/trigger/1.trigger",
         "asset:artifact/0566.great_sage_helmet/kill/1.trigger",
         "asset:artifact/0950.residue_of_pumpkin/trigger/1.trigger",
         "asset:artifact/1083.tablet_of_oracle/trigger/1.trigger"
     ]
-}
+}

Asset/data/asset/tags/functions/artifact/register.json

@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:artifact/1314.topaz_broach/register",
         "asset:artifact/1137.over_pulse_headgear/register",
         "asset:artifact/1228.fatalerror/register",
         "asset:artifact/1273.maidchan_plush/register",
@@ -295,4 +296,4 @@
         "asset:artifact/1027.fire_of_rebirth/register",
         "asset:artifact/1111.rod_o_redeem/register"
     ]
-}
+}