✨ [Artifact 1332] ビビビームを作成

Asset/data/asset/functions/artifact/1332.bebebeam/give/1.trigger.mcfunction

@@ -0,0 +1,7 @@
+#> asset:artifact/1332.bebebeam/give/1.trigger
+#
+# 神器の取得処理の呼び出し時に実行されるfunction
+#
+# @within tag/function asset:artifact/give
+
+execute if data storage asset:context {id:1332} run function asset:artifact/1332.bebebeam/give/2.give

Asset/data/asset/functions/artifact/1332.bebebeam/give/2.give.mcfunction

@@ -0,0 +1,68 @@
+#> asset:artifact/1332.bebebeam/give/2.give
+#
+# 神器の作成部 ここでID等を定義する
+#
+# @user
+# @within function asset:artifact/1332.bebebeam/give/1.trigger
+
+# 神器の説明や消費MPなどをここで設定する。
+# 最後にasset:artifact/common/giveを実行することで入手可能。
+
+# 神器のID (int) スプレッドシートの値を入れる
+    data modify storage asset:artifact ID set value 1332
+# 神器のベースアイテム
+    data modify storage asset:artifact Item set value "minecraft:carrot_on_a_stick"
+# 神器の名前 (TextComponentString)
+    data modify storage asset:artifact Name set value '{"text":"ビビビーム","color":"light_purple"}'
+# 神器の説明文 (TextComponentString[])
+    data modify storage asset:artifact Lore set value ['[{"translate":"%1$s・%2$s・%3$s属性の順に、連続でビームを放つ","color":"white","with":[{"text":"火","color":"red"},{"text":"水","color":"aqua"},{"text":"雷","color":"yellow"}]}]','[{"text":"この神器をホットバーに追加で1本持つたびに、発射数が1本増加する","color":"white"}]']
+# 消費アイテム ({Item: TextComponent, Count: int, Extra?: TextComponent}) (オプション)
+    # data modify storage asset:artifact ConsumeItem.Item set value '{"translate":"item.minecraft.stick"}'
+    # data modify storage asset:artifact ConsumeItem.Count set value 1
+    # data modify storage asset:artifact ConsumeItem.Extra set value
+# 使用回数 (int) (オプション)
+    # data modify storage asset:artifact RemainingCount set value
+# 神器を発動できるスロット (string) Wikiを参照
+    data modify storage asset:artifact Slot set value "mainhand"
+# 神器のトリガー (string) Wikiを参照
+    data modify storage asset:artifact Trigger set value "onClick"
+# 神器の発動条件 (TextComponentString) (オプション)
+    # data modify storage asset:artifact Condition set value
+# 攻撃に関する情報 -Damage量 (literal[]/literal) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.Damage set value "60-80x3"
+# 攻撃に関する情報 -攻撃タイプ (string[]) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.AttackType set value [Magic]
+# 攻撃に関する情報 -攻撃属性 (string[]) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.ElementType set value [Fire,Water,Thunder]
+# 攻撃に関する情報 -防御無視 (boolean) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.BypassResist set value
+# 攻撃に関する情報 -範囲攻撃 (string) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.IsRangeAttack set value "never"
+# 攻撃に関する情報 -攻撃範囲 (literal) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.AttackRange set value 16
+# MP消費量 (int)
+    data modify storage asset:artifact MPCost set value 50
+# MP必要量 (int) (オプション)
+    # data modify storage asset:artifact MPRequire set value
+# MP回復量 (int)
+    # data modify storage asset:artifact MPHealWhenHit set value
+# 神器のクールダウン (int) (オプション)
+    # data modify storage asset:artifact LocalCooldown set value
+# 種別クールダウン ({Type: string, Duration: int}) (オプション)
+    data modify storage asset:artifact TypeCooldown.Type set value "longRange"
+    data modify storage asset:artifact TypeCooldown.Duration set value 60
+# グローバルクールダウン (int) (オプション)
+    # data modify storage asset:artifact SpecialCooldown set value
+# クールダウンによる使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    # data modify storage asset:artifact DisableCooldownMessage set value
+# MP不足による使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    # data modify storage asset:artifact DisableMPMessage set value
+# 破壊時の音を鳴らさないかどうか (boolean) (オプション)
+    # data modify storage asset:artifact DisableBreakSound set value
+# 扱える神 (string[]) Wikiを参照
+    data modify storage asset:artifact CanUsedGod set value ["Flora", "Nyaptov", "Wi-ki"]
+# カスタムNBT (NBTCompound) 追加で指定したいNBT (オプション)
+    # data modify storage asset:artifact CustomNBT set value {}
+
+# 神器の入手用function
+    function asset:artifact/common/give

Asset/data/asset/functions/artifact/1332.bebebeam/register.mcfunction

@@ -0,0 +1,7 @@
+#> asset:artifact/1332.bebebeam/register
+#
+# 神器プールへの登録処理
+#
+# @within tag/function asset:artifact/register
+
+data modify storage asset:artifact RarityRegistry[2] append value [1332]

Asset/data/asset/functions/artifact/1332.bebebeam/trigger/0.load.mcfunction

@@ -0,0 +1,11 @@
+#> asset:artifact/1332.bebebeam/trigger/0.load
+#
+# 神器に利用するスコアボード等の初期化処理
+#
+# @within tag/function asset:artifact/load
+
+#> 定義類はここに
+# @within function asset:artifact/1332.bebebeam/trigger/**
+    scoreboard objectives add 110.Tick dummy
+    scoreboard objectives add 110.Count dummy
+    scoreboard objectives add 110.Element dummy

Asset/data/asset/functions/artifact/1332.bebebeam/trigger/1.trigger.mcfunction

@@ -0,0 +1,8 @@
+#> asset:artifact/1332.bebebeam/trigger/1.trigger
+#
+# 指定したイベントタイミングで実行されるfunction
+#
+# @within tag/function asset:artifact/**
+
+# storage asset:idのmainhandに装備している神器のIDが入っているので比較し、~/2.check_condition.mcfunctionを実行する
+    execute if data storage asset:context id{mainhand:1332} run function asset:artifact/1332.bebebeam/trigger/2.check_condition

Asset/data/asset/functions/artifact/1332.bebebeam/trigger/2.check_condition.mcfunction

@@ -0,0 +1,12 @@
+#> asset:artifact/1332.bebebeam/trigger/2.check_condition
+#
+# 神器の発動条件をチェックします
+#
+# @within function asset:artifact/1332.bebebeam/trigger/1.trigger
+
+# 神器の基本的な条件の確認を行うfunction、成功している場合CanUsedタグが付く
+    function asset:artifact/common/check_condition/mainhand
+# 他にアイテム等確認する場合はここに書く
+
+# CanUsedタグをチェックして3.main.mcfunctionを実行する
+    execute if entity @s[tag=CanUsed] run function asset:artifact/1332.bebebeam/trigger/3.main

Asset/data/asset/functions/artifact/1332.bebebeam/trigger/3.main.mcfunction

@@ -0,0 +1,29 @@
+#> asset:artifact/1332.bebebeam/trigger/3.main
+#
+# 神器のメイン処理部
+#
+# @within function asset:artifact/1332.bebebeam/trigger/2.check_condition
+
+# 基本的な使用時の処理(MP消費や使用回数の処理など)を行う
+    function asset:artifact/common/use/mainhand
+
+# ここから先は神器側の効果の処理を書く
+
+# 個数取得
+    execute store result score @s 110.Count if data storage asset:context Items.hotbar[{tag:{TSB:{ID:1332}}}]
+
+# 個数+2を発射数とする
+    scoreboard players add @s 110.Count 2
+
+# スコア初期化
+    scoreboard players set @s 110.Tick 0
+    scoreboard players set @s 110.Element -1
+
+# まず1発発射する
+    function asset:artifact/1332.bebebeam/trigger/beam/
+
+# ループ開始
+    schedule function asset:artifact/1332.bebebeam/trigger/loop/ 1t replace
+
+# リセット
+    # scoreboard players reset @s 110.Count

Asset/data/asset/functions/artifact/1332.bebebeam/trigger/_index.d.mcfunction

@@ -0,0 +1,6 @@
+#> asset:artifact/1332.bebebeam/trigger/_index.d
+# @private
+
+#> tag
+# @within function asset:artifact/1332.bebebeam/trigger/**
+    #declare score_holder $110.Range

Asset/data/asset/functions/artifact/1332.bebebeam/trigger/beam/.mcfunction

@@ -0,0 +1,32 @@
+#> asset:artifact/1332.bebebeam/trigger/beam/
+#
+#
+#
+# @within function
+#   asset:artifact/1332.bebebeam/trigger/3.main
+#   asset:artifact/1332.bebebeam/trigger/loop/main
+
+#> Private
+# @private
+    #declare tag SpreadMarker
+
+# 演出
+    playsound tsb_sounds:blaster2 player @a ~ ~ ~ 0.2 1.8
+    playsound ogg:block.respawn_anchor.deplete2 player @a ~ ~ ~ 0.7 1.5
+
+# 発射数のデクリメント
+    scoreboard players remove @s 110.Count 1
+
+# 属性管理スコアの管理
+# 0:火, 1:水, 2:雷
+# インクリメントし、3以上なら0に戻す
+    scoreboard players add @s 110.Element 1
+    execute if score @s 110.Element matches 3.. run scoreboard players set @s 110.Element 0
+
+# 実行位置を拡散させランダムにする
+    summon marker ~ ~ ~ {Tags:["SpreadMarker"]}
+    data modify storage lib: Argument.Distance set value 0.5
+    data modify storage lib: Argument.Spread set value 0.5
+    execute as @e[type=marker,tag=SpreadMarker,distance=..5,limit=1] run function lib:forward_spreader/circle
+    execute positioned as @e[type=marker,tag=SpreadMarker,distance=..5,limit=1] run function asset:artifact/1332.bebebeam/trigger/beam/shoot
+    kill @e[type=marker,tag=SpreadMarker,distance=..5]

Asset/data/asset/functions/artifact/1332.bebebeam/trigger/beam/damage.mcfunction

@@ -0,0 +1,17 @@
+#> asset:artifact/1332.bebebeam/trigger/beam/damage
+#
+#
+#
+# @within function asset:artifact/1332.bebebeam/trigger/beam/recursive
+
+# 属性設定
+    execute if score @s 110.Element matches 0 run data modify storage api: Argument.ElementType set value "Fire"
+    execute if score @s 110.Element matches 1 run data modify storage api: Argument.ElementType set value "Water"
+    execute if score @s 110.Element matches 2 run data modify storage api: Argument.ElementType set value "Thunder"
+
+# ダメージ
+    execute store result storage api: Argument.Damage float 1 run random value 60..80
+    data modify storage api: Argument.AttackType set value "Magic"
+    function api:damage/modifier
+    execute as @e[type=#lib:living,tag=Enemy,tag=!Uninterferable,dx=0,sort=random,limit=1] run function api:damage/
+    function api:damage/reset

Asset/data/asset/functions/artifact/1332.bebebeam/trigger/beam/recursive.mcfunction

@@ -0,0 +1,21 @@
+#> asset:artifact/1332.bebebeam/trigger/beam/recursive
+#
+#
+#
+# @within function
+#   asset:artifact/1332.bebebeam/trigger/beam/shoot
+#   asset:artifact/1332.bebebeam/trigger/beam/recursive
+
+# Rangeのインクリメント
+    scoreboard players add $110.Range Temporary 1
+
+# 演出
+    execute if score @s 110.Element matches 0 run particle dust 0.8 0.4 0 0.5 ~ ~ ~ 0.05 0.05 0.05 0 1
+    execute if score @s 110.Element matches 1 run particle dust 0.216 0.675 1 0.5 ~ ~ ~ 0.05 0.05 0.05 0 1
+    execute if score @s 110.Element matches 2 run particle dust 1 0.976 0.337 0.5 ~ ~ ~ 0.05 0.05 0.05 0 1
+
+# 敵がいたらダメージを与え、再帰終了
+    execute positioned ~-0.5 ~-0.5 ~-0.5 if entity @e[type=#lib:living_without_player,tag=Enemy,tag=!Uninterferable,dx=0,limit=1] run return run function asset:artifact/1332.bebebeam/trigger/beam/damage
+
+# 再帰
+    execute if score $110.Range Temporary matches ..32 positioned ^ ^ ^0.5 if block ~ ~ ~ #lib:no_collision/ run function asset:artifact/1332.bebebeam/trigger/beam/recursive

Asset/data/asset/functions/artifact/1332.bebebeam/trigger/beam/shoot.mcfunction

@@ -0,0 +1,15 @@
+#> asset:artifact/1332.bebebeam/trigger/beam/shoot
+#
+#
+#
+# @within function asset:artifact/1332.bebebeam/trigger/beam/
+
+# 再帰でヒット判定 兼 演出用に何ブロックまで視線が通っているかチェック
+    scoreboard players set $110.Range Temporary 0
+    execute anchored eyes positioned ^ ^ ^ run function asset:artifact/1332.bebebeam/trigger/beam/recursive
+
+# レーザー演出Object召喚
+    function asset:artifact/1332.bebebeam/trigger/beam/summon_object
+
+# リセット
+    scoreboard players reset $110.Range

Asset/data/asset/functions/artifact/1332.bebebeam/trigger/beam/summon_object.mcfunction

@@ -0,0 +1,18 @@
+#> asset:artifact/1332.bebebeam/trigger/beam/summon_object
+#
+#
+#
+# @within function asset:artifact/1332.bebebeam/trigger/beam/shoot
+
+#  データ設定
+    data modify storage api: Argument.ID set value 2168
+    data modify storage api: Argument.FieldOverride set value {Scale:[0.25f,0f,0.25f],Color:0,DisappearInterpolation:2,LifeTime:7}
+    execute store result storage api: Argument.FieldOverride.Scale[1] float 1 run scoreboard players get $110.Range Temporary
+
+# 属性に応じて色を変える
+    execute if score @s 110.Element matches 0 run data modify storage api: Argument.FieldOverride.Color set value 16728852
+    execute if score @s 110.Element matches 1 run data modify storage api: Argument.FieldOverride.Color set value 4685567
+    execute if score @s 110.Element matches 2 run data modify storage api: Argument.FieldOverride.Color set value 16772431
+
+# 召喚
+    execute anchored eyes positioned ^ ^0 ^0.4 run function api:object/summon

Asset/data/asset/functions/artifact/1332.bebebeam/trigger/loop/.mcfunction

@@ -0,0 +1,11 @@
+#> asset:artifact/1332.bebebeam/trigger/loop/
+#
+#
+#
+# @within function
+#   asset:artifact/1332.bebebeam/trigger/3.main
+#   asset:artifact/1332.bebebeam/trigger/loop/main
+#   asset:artifact/1332.bebebeam/trigger/rejoin_process
+
+#
+    execute as @a[scores={110.Count=1..}] at @s run function asset:artifact/1332.bebebeam/trigger/loop/main

Asset/data/asset/functions/artifact/1332.bebebeam/trigger/loop/main.mcfunction

@@ -0,0 +1,24 @@
+#> asset:artifact/1332.bebebeam/trigger/loop/main
+#
+#
+#
+# @within function asset:artifact/1332.bebebeam/trigger/loop/
+
+#> Private
+# @private
+    #declare score_holder $110.Interval
+
+# Tickのインクリメント
+    scoreboard players add @s 110.Tick 1
+
+# Ntickに1回発射
+    scoreboard players operation $110.Interval Temporary = @s 110.Tick
+    scoreboard players operation $110.Interval Temporary %= $4 Const
+    execute if score $110.Interval Temporary matches 0 run function asset:artifact/1332.bebebeam/trigger/beam/
+    scoreboard players reset $110.Interval Temporary
+
+# Countが0ならリセット
+    execute if score @s 110.Count matches ..0 run function asset:artifact/1332.bebebeam/trigger/reset
+
+# ループ
+    schedule function asset:artifact/1332.bebebeam/trigger/loop/ 1t replace

Asset/data/asset/functions/artifact/1332.bebebeam/trigger/rejoin_process.mcfunction

@@ -0,0 +1,8 @@
+#> asset:artifact/1332.bebebeam/trigger/rejoin_process
+#
+# 使い方は必ずwikiを見ること
+#
+# @within tag/function asset:rejoin
+
+# ループ
+    schedule function asset:artifact/1332.bebebeam/trigger/loop/ 1t replace

Asset/data/asset/functions/artifact/1332.bebebeam/trigger/reset.mcfunction

@@ -0,0 +1,10 @@
+#> asset:artifact/1332.bebebeam/trigger/reset
+#
+#
+#
+# @within function asset:artifact/1332.bebebeam/trigger/loop/main
+
+# スコアを諸々リセット
+    scoreboard players reset @s 110.Tick
+    scoreboard players reset @s 110.Count
+    scoreboard players reset @s 110.Element

Asset/data/asset/tags/functions/artifact/click.carrot_on_a_stick.json

@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:artifact/1332.bebebeam/trigger/1.trigger",
         "asset:artifact/0005.musket_matchlock/trigger/1.trigger",
         "asset:artifact/0017.harmful_books/trigger/1.trigger",
         "asset:artifact/0075.whirlpool_wand/trigger/1.trigger",
@@ -90,7 +91,6 @@
         "asset:artifact/1265.thunder_ray/trigger/1.trigger",
         "asset:artifact/1270.raging_passion_pickaxe/trigger/1.trigger",
         "asset:artifact/1272.big_water_launcher/trigger/1.trigger",
-
         "asset:artifact/0001.book_of_all-seeing/trigger/1.trigger",
         "asset:artifact/0002.blessing/trigger/1.trigger",
         "asset:artifact/0007.nitrogen_fixater/trigger/1.trigger",
@@ -175,8 +175,6 @@
         "asset:artifact/1284.quiver/trigger/1.trigger",
         "asset:artifact/1285.torch_bag/trigger/1.trigger",
         "asset:artifact/2001.staff_of_the_willless/trigger/1.trigger",
-
         "asset:artifact/0019.scripture/trigger/1.trigger"
-
     ]
-}
+}

Asset/data/asset/tags/functions/artifact/give.json

@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:artifact/1332.bebebeam/give/1.trigger",
         "asset:artifact/1140.over_pulse_booster/give/1.trigger",
         "asset:artifact/1139.over_pulse_legframe/give/1.trigger",
         "asset:artifact/1138.over_pulse_bodyarmor/give/1.trigger",
@@ -517,4 +518,4 @@
         "asset:artifact/0735.collision_plate/give/1.trigger",
         "asset:artifact/0745.blade_of_whirlwind/give/1.trigger"
     ]
-}
+}

Asset/data/asset/tags/functions/artifact/load.json

@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:artifact/1332.bebebeam/trigger/0.load",
         "asset:artifact/1220.sacred_hardener/trigger/0.load",
         "asset:artifact/1269.apocalypse/trigger/0.load",
         "asset:artifact/1061.hekireki/trigger/0.load",
@@ -59,4 +60,4 @@
         "asset:artifact/0270.angel_ray_lv.10/trigger/0.load",
         "asset:artifact/0431.weather_lock_cane/trigger/0.load"
     ]
-}
+}

Asset/data/asset/tags/functions/artifact/register.json

@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:artifact/1332.bebebeam/register",
         "asset:artifact/1137.over_pulse_headgear/register",
         "asset:artifact/1228.fatalerror/register",
         "asset:artifact/1273.maidchan_plush/register",
@@ -295,4 +296,4 @@
         "asset:artifact/1027.fire_of_rebirth/register",
         "asset:artifact/1111.rod_o_redeem/register"
     ]
-}
+}