Migrated to OZ v5

.env.example

@@ -1,12 +1 @@
-# Deployer private key
-PRIVATE_KEY=YOUR PRIVATE KEY
-
-# RPC Endpoints
-INFURA_KEY=INFURA PROJECT ID
-
-# Additional keys
-ETHERSCAN_KEY=ETHERSCAN API KEY
-BSCSCAN_KEY=BSCSCAN API KEY
-POLYGONSCAN_KEY=POLYGONSCAN API KEY
-AVALANCHE_KEY=AVALANCHE API KEY
 COINMARKETCAP_KEY=COINMARKETCAP API KEY

.solhint.json

@@ -9,6 +9,8 @@
     "func-visibility": "off",
     "max-states-count": "off",
     "not-rely-on-time": "off",
-    "compiler-version": "off"
+    "compiler-version": "off",
+    "func-name-mixedcase": "off",
+    "no-inline-assembly": "off"
   }
 }

README.md

@@ -5,25 +5,29 @@
 
 Bring Real World Assets (RWA) on-chain via flexible tokenization framework - TokenF.
 
-!["TokenF Architecture"](https://github.com/dl-tokenf/core-contracts/assets/47551140/9e912d07-bc4d-407d-bf25-859e0da40f32)
+TokenF and NFTF architecture:
+
+!["AssetF Architecture"](https://github.com/user-attachments/assets/ef4b0bd1-c078-47d4-bd0c-7b7052f920b0)
+
+Built with [Solarity](https://github.com/dl-solarity), [OpenZeppelin](https://github.com/OpenZeppelin/openzeppelin-contracts), and aspiration to perfection.
 
-Built with [Solarity](https://github.com/dl-solarity), [Openzeppelin](https://github.com/OpenZeppelin/openzeppelin-contracts), and aspiration to perfection.
 
 ## Application
 
-TokenF is an on-chain framework that enables development, management, and deployment of permissioned ERC-20-compatible assets on EVM networks. TokenF enables custom rules to be configured for RWA tokens, providing flexible KYC/AML and regulatory compliance checks for the users to abide during interaction with the smart contracts.
+TokenF is an on-chain framework that enables development, management, and deployment of permissioned ERC-20-compatible and ERC-721-compatible assets on EVM networks. TokenF enables custom rules to be configured for RWA tokens, providing flexible KYC/AML and regulatory compliance checks for the users to abide during interaction with the smart contracts.
 
-TokenF is built with certain levels of abstraction in mind: 
+TokenF is built with certain levels of abstraction in mind:
 
 - ERC-2535 Diamond beating heart that allows extensibility and upgradeability.
 - Support of custom compliance modules to be plugged in the TokenF core.
 - Rich configuration of check/hooks/behavior with imagination being the only limit.
 
-| **What TokenF Is ✅**                        | **What TokenF Is Not ❌**        |
-| :-----------------------------------------:  | :------------------------------: |
-| On-chain tokenization framework              | Fullstack tokenization framework |
-| Smart contracts to configure RWA behavior    | RWA launchpad/RWA consulting set |
-| Reimagined and enhanced ERC-3643 alternative | Yet another ERC-3643 copy        |
+| **What TokenF Is ✅**                        | **What TokenF Is Not ❌**           |
+| :-----------------------------------------:  | :---------------------------------: |
+| On-chain tokenization framework              | Fullstack tokenization framework    |
+| Smart contracts to configure RWA behavior    | RWA launchpad/RWA consulting set    |
+| Built from scratch ERC-3643 alternative      | Yet another ERC-3643 copy           |
+| Support of both ERC-20 and ERC-721 standards | Currently does not support ERC-1155 |
 
 > [!NOTE]
 > TokenF is at the early stage of development, many breaking changes are foreseen.
@@ -41,13 +45,20 @@ npm install @tokenf/contracts
 You will then be able to start using TokenF:
 
 ```solidity
-pragma solidity ^0.8.20;
+pragma solidity ^0.8.21;
 
-import {TokenF} from "@tokenf/contracts/core/TokenF.sol";
+import {TokenF} from "@tokenf/contracts/TokenF.sol";
+import {NFTF} from "@tokenf/contracts/NFTF.sol";
 
 contract EquityToken is TokenF {
     . . .
 }
+
+// or
+
+contract LandNft is NFTF {
+    . . .
+}
 ```
 
 > [!TIP]

contracts/NFTF.sol

@@ -0,0 +1,301 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.21;
+
+import {IERC721} from "@openzeppelin/contracts/interfaces/IERC721.sol";
+import {IERC721Metadata} from "@openzeppelin/contracts/token/ERC721/extensions/IERC721Metadata.sol";
+import {ERC721EnumerableUpgradeable, ERC721Upgradeable, IERC165} from "@openzeppelin/contracts-upgradeable/token/ERC721/extensions/ERC721EnumerableUpgradeable.sol";
+
+import {Diamond} from "@solarity/solidity-lib/diamond/Diamond.sol";
+
+import {INFTF} from "./interfaces/INFTF.sol";
+import {IKYCCompliance} from "./interfaces/core/IKYCCompliance.sol";
+import {IRegulatoryCompliance} from "./interfaces/core/IRegulatoryCompliance.sol";
+
+import {AgentAccessControl, AccessControlUpgradeable} from "./core/AgentAccessControl.sol";
+import {NFTFStorage} from "./storages/NFTFStorage.sol";
+import {RegulatoryComplianceStorage} from "./storages/core/RegulatoryComplianceStorage.sol";
+import {KYCComplianceStorage} from "./storages/core/KYCComplianceStorage.sol";
+
+abstract contract NFTF is
+    INFTF,
+    NFTFStorage,
+    Diamond,
+    ERC721EnumerableUpgradeable,
+    AgentAccessControl
+{
+    bytes4 public constant TRANSFER_SELECTOR = this.transfer.selector;
+    bytes4 public constant TRANSFER_FROM_SELECTOR = this.transferFrom.selector;
+    bytes4 public constant MINT_SELECTOR = this.mint.selector;
+    bytes4 public constant BURN_SELECTOR = this.burn.selector;
+    bytes4 public constant FORCED_TRANSFER_SELECTOR = this.forcedTransfer.selector;
+    bytes4 public constant RECOVERY_SELECTOR = this.recovery.selector;
+
+    function __NFTF_init(
+        address regulatoryCompliance_,
+        address kycCompliance_,
+        bytes memory initRegulatory_,
+        bytes memory initKYC_
+    ) internal virtual onlyInitializing {
+        bytes4[] memory rComplianceSelectors_ = new bytes4[](6);
+        rComplianceSelectors_[0] = IRegulatoryCompliance.addRegulatoryModules.selector;
+        rComplianceSelectors_[1] = IRegulatoryCompliance.removeRegulatoryModules.selector;
+        rComplianceSelectors_[2] = IRegulatoryCompliance.transferred.selector;
+        rComplianceSelectors_[3] = IRegulatoryCompliance.canTransfer.selector;
+        rComplianceSelectors_[4] = RegulatoryComplianceStorage.getRegulatoryModules.selector;
+        rComplianceSelectors_[5] = RegulatoryComplianceStorage.getRegulatoryModulesCount.selector;
+
+        bytes4[] memory kycComplianceSelectors_ = new bytes4[](5);
+        kycComplianceSelectors_[0] = IKYCCompliance.addKYCModules.selector;
+        kycComplianceSelectors_[1] = IKYCCompliance.removeKYCModules.selector;
+        kycComplianceSelectors_[2] = IKYCCompliance.isKYCed.selector;
+        kycComplianceSelectors_[3] = KYCComplianceStorage.getKYCModules.selector;
+        kycComplianceSelectors_[4] = KYCComplianceStorage.getKYCModulesCount.selector;
+
+        Facet[] memory facets_ = new Facet[](2);
+        facets_[0] = Facet(regulatoryCompliance_, FacetAction.Add, rComplianceSelectors_);
+        facets_[1] = Facet(kycCompliance_, FacetAction.Add, kycComplianceSelectors_);
+
+        _diamondCut(facets_, address(0), "");
+        _diamondCut(new Facet[](0), regulatoryCompliance_, initRegulatory_);
+        _diamondCut(new Facet[](0), kycCompliance_, initKYC_);
+    }
+
+    /// @inheritdoc INFTF
+    function transfer(address to_, uint256 tokenId_) public virtual override {
+        _canTransfer(msg.sender, to_, tokenId_, address(0));
+        _isKYCed(msg.sender, to_, tokenId_, address(0));
+
+        super._transfer(msg.sender, to_, tokenId_);
+
+        _transferred(msg.sender, to_, tokenId_, address(0));
+    }
+
+    /// @inheritdoc IERC721
+    function transferFrom(
+        address from_,
+        address to_,
+        uint256 tokenId_
+    ) public virtual override(ERC721Upgradeable, IERC721) {
+        _canTransfer(from_, to_, tokenId_, msg.sender);
+        _isKYCed(from_, to_, tokenId_, msg.sender);
+
+        super.transferFrom(from_, to_, tokenId_);
+
+        _transferred(from_, to_, tokenId_, msg.sender);
+    }
+
+    /// @inheritdoc INFTF
+    function mint(
+        address account_,
+        uint256 tokenId_,
+        string memory tokenURI_
+    ) public virtual override onlyRole(_mintRole()) {
+        _canTransfer(address(0), account_, tokenId_, msg.sender);
+        _isKYCed(address(0), account_, tokenId_, msg.sender);
+
+        super._mint(account_, tokenId_);
+        _setTokenURI(tokenId_, tokenURI_);
+
+        _transferred(address(0), account_, tokenId_, msg.sender);
+    }
+
+    /// @inheritdoc INFTF
+    function burn(uint256 tokenId_) public virtual override onlyRole(_burnRole()) {
+        address account_ = _ownerOf(tokenId_);
+
+        _canTransfer(account_, address(0), tokenId_, msg.sender);
+        _isKYCed(account_, address(0), tokenId_, msg.sender);
+
+        super._burn(tokenId_);
+
+        _transferred(account_, address(0), tokenId_, msg.sender);
+    }
+
+    /// @inheritdoc INFTF
+    function forcedTransfer(
+        address from_,
+        address to_,
+        uint256 tokenId_
+    ) public virtual override onlyRole(_forcedTransferRole()) {
+        _canTransfer(from_, to_, tokenId_, msg.sender);
+        _isKYCed(from_, to_, tokenId_, msg.sender);
+
+        super._transfer(from_, to_, tokenId_);
+
+        _transferred(from_, to_, tokenId_, msg.sender);
+    }
+
+    /// @inheritdoc INFTF
+    function recovery(
+        address oldAccount_,
+        address newAccount_
+    ) public virtual override onlyRole(_recoveryRole()) {
+        uint256 oldBalance_ = balanceOf(oldAccount_);
+
+        for (uint256 i = oldBalance_; i > 0; --i) {
+            uint256 tokenId_ = tokenOfOwnerByIndex(oldAccount_, i - 1);
+
+            _canTransfer(oldAccount_, newAccount_, tokenId_, msg.sender);
+            _isKYCed(oldAccount_, newAccount_, tokenId_, msg.sender);
+
+            super._transfer(oldAccount_, newAccount_, tokenId_);
+
+            _transferred(oldAccount_, newAccount_, tokenId_, msg.sender);
+        }
+    }
+
+    /// @inheritdoc INFTF
+    function diamondCut(
+        Facet[] memory modules_
+    ) public virtual override onlyRole(_diamondCutRole()) {
+        diamondCut(modules_, address(0), "");
+    }
+
+    /// @inheritdoc INFTF
+    function diamondCut(
+        Facet[] memory modules_,
+        address initModule_,
+        bytes memory initData_
+    ) public virtual override onlyRole(_diamondCutRole()) {
+        _diamondCut(modules_, initModule_, initData_);
+    }
+
+    /// @inheritdoc INFTF
+    function setBaseURI(string memory baseURI_) public virtual override onlyRole(_uriRole()) {
+        _getNftFStorage().baseURI = baseURI_;
+    }
+
+    /// @inheritdoc INFTF
+    function setTokenURI(
+        uint256 tokenId_,
+        string memory tokenURI_
+    ) public virtual override onlyRole(_uriRole()) {
+        _requireOwned(tokenId_);
+
+        _setTokenURI(tokenId_, tokenURI_);
+    }
+
+    /**
+     * @inheritdoc IERC721Metadata
+     *
+     * @dev
+     * If the token does not exist, an empty string is returned.
+     * If a tokenURI is set for the token, it will be returned.
+     * If a base URI is set, the concatenation of the base URI and tokenId is returned.
+     * Otherwise, an empty string is returned.
+     */
+    function tokenURI(
+        uint256 tokenId_
+    ) public view virtual override(IERC721Metadata, ERC721Upgradeable) returns (string memory) {
+        address owner_ = _ownerOf(tokenId_);
+
+        if (owner_ == address(0)) {
+            return "";
+        }
+
+        NftFStorage storage $ = _getNftFStorage();
+        string memory tokenURI_ = $.tokenURIs[tokenId_];
+
+        if (bytes(tokenURI_).length > 0) {
+            return tokenURI_;
+        }
+
+        return super.tokenURI(tokenId_);
+    }
+
+    /// @inheritdoc IERC165
+    function supportsInterface(
+        bytes4 interfaceId_
+    )
+        public
+        view
+        override(AccessControlUpgradeable, ERC721EnumerableUpgradeable, IERC165)
+        returns (bool)
+    {
+        return super.supportsInterface(interfaceId_);
+    }
+
+    function _setTokenURI(uint256 tokenId_, string memory tokenURI_) internal virtual {
+        NftFStorage storage $ = _getNftFStorage();
+        $.tokenURIs[tokenId_] = tokenURI_;
+
+        emit MetadataUpdate(tokenId_);
+    }
+
+    function _transferred(
+        address from_,
+        address to_,
+        uint256 tokenId_,
+        address operator_
+    ) internal virtual {
+        try
+            IRegulatoryCompliance(address(this)).transferred(
+                Context(bytes4(bytes(msg.data[:4])), from_, to_, 0, tokenId_, operator_, "")
+            )
+        {} catch {
+            revert TransferredReverted();
+        }
+    }
+
+    function _canTransfer(
+        address from_,
+        address to_,
+        uint256 tokenId_,
+        address operator_
+    ) internal view virtual {
+        try
+            IRegulatoryCompliance(address(this)).canTransfer(
+                Context(bytes4(bytes(msg.data[:4])), from_, to_, 0, tokenId_, operator_, "")
+            )
+        returns (bool canTransfer_) {
+            require(canTransfer_, CannotTransfer());
+        } catch {
+            revert CanTransferReverted();
+        }
+    }
+
+    function _isKYCed(
+        address from_,
+        address to_,
+        uint256 tokenId_,
+        address operator_
+    ) internal view virtual {
+        try
+            IKYCCompliance(address(this)).isKYCed(
+                Context(bytes4(bytes(msg.data[:4])), from_, to_, 0, tokenId_, operator_, "")
+            )
+        returns (bool isKYCed_) {
+            require(isKYCed_, NotKYCed());
+        } catch {
+            revert IsKYCedReverted();
+        }
+    }
+
+    function _baseURI() internal view virtual override returns (string memory) {
+        return _getNftFStorage().baseURI;
+    }
+
+    function _mintRole() internal view virtual returns (bytes32) {
+        return AGENT_ROLE;
+    }
+
+    function _burnRole() internal view virtual returns (bytes32) {
+        return AGENT_ROLE;
+    }
+
+    function _forcedTransferRole() internal view virtual returns (bytes32) {
+        return AGENT_ROLE;
+    }
+
+    function _recoveryRole() internal view virtual returns (bytes32) {
+        return AGENT_ROLE;
+    }
+
+    function _diamondCutRole() internal view virtual returns (bytes32) {
+        return AGENT_ROLE;
+    }
+
+    function _uriRole() internal view virtual returns (bytes32) {
+        return AGENT_ROLE;
+    }
+}