Issue1436 PVT model

.gitattributes

@@ -1,17 +1,16 @@
 # Set default behaviour, in case users don't have core.autocrlf set.
 * text=auto
-
 # Explicitly declare text files we want to always be normalized and converted 
 # to native line endings on checkout.
 *.mo text
 *.mos text
 *.mop text
 *.py text
 *.txt text
-
 # Declare files that will always have CRLF line endings on checkout.
 #*.sln text eol=crlf
-
 # Denote all files that are truly binary and should not be modified.
 *.png binary
 *.jpg binary
+IDEAS/Resources/Data/Fluid/PvtCollectors/Validation/PVT2/PVT2_Austria_wheaterData.mos filter=lfs diff=lfs merge=lfs -text
+IDEAS/Resources/Data/Fluid/PvtCollectors/Validation/PVT2/PVT2_measurements.txt filter=lfs diff=lfs merge=lfs -text

IDEAS/.gitattributes

@@ -0,0 +1,4 @@
+IDEAS/Resources/Data/Fluid/PvtCollectors/Validation/PVT2/*.mos filter=lfs diff=lfs merge=lfs -text
+IDEAS/Resources/Data/Fluid/PvtCollectors/Validation/PVT2/*.txt filter=lfs diff=lfs merge=lfs -text
+IDEAS/Resources/Data/Fluid/PvtCollectors/Validation/PVT2/PVT2_Austria_wheaterData.mos filter=lfs diff=lfs merge=lfs -text
+IDEAS/Resources/Data/Fluid/PvtCollectors/Validation/PVT2/PVT2_measurements.txt filter=lfs diff=lfs merge=lfs -text

IDEAS/Fluid/PvtCollectors/BaseClasses/ElectricalPVT.mo

@@ -0,0 +1,216 @@
+within IDEAS.Fluid.PVTCollectors.BaseClasses;
+model ElectricalPVT "Visible block to compute electrical power output using PVWatts v5 approach"
+  extends Modelica.Blocks.Icons.Block;
+  extends SolarCollectors.BaseClasses.PartialParameters;
+  // Parameters
+  parameter Integer nSeg = 1 "Number of segments";
+  parameter Modelica.Units.SI.Irradiance HGloHorNom = 1000 "Nominal global irradiance";
+  parameter Modelica.Units.SI.Efficiency pLossFactor = 0.10 "PV loss factor";
+  parameter Modelica.Units.SI.Temperature TpvtRef = 298.15 "Reference cell temperature [K]";
+  parameter Real gamma "Temperature coefficient [1/K]";
+  parameter Real P_nominal "Nominal PV power [W]";
+  parameter Real A "PV area [m2]";
+  parameter Real eta0 "Zero-loss efficiency";
+  parameter Real tauAlphaEff "Effective transmittance–absorptance product";
+  parameter Real c1 "First-order heat loss coefficient";
+  parameter Real etaEl "Electrical efficiency";
+
+  final parameter Modelica.Units.SI.CoefficientOfHeatTransfer UAbsFluid =
+  ((tauAlphaEff - etaEl) * (c1 + abs(gamma)*HGloHorNom))
+  / ((tauAlphaEff - etaEl) - eta0)
+  "Heat transfer coefficient between the fluid and the PV cells, calculated from datasheet parameters";
+
+  // Inputs
+  Modelica.Blocks.Interfaces.RealInput Tm[nSeg]
+    "Fluid temperatures per segment [K]"
+    annotation (Placement(transformation(extent={{-140,40},{-100,80}}),
+        iconTransformation(extent={{-140,40},{-100,80}})));
+  Modelica.Blocks.Interfaces.RealInput qth[nSeg]
+    "Thermal power density per segment [W/m2]"
+    annotation (Placement(transformation(extent={{-140,-20},{-100,20}}),
+        iconTransformation(extent={{-140,-20},{-100,20}})));
+  Modelica.Blocks.Interfaces.RealInput HGloTil
+    "Global tilted irradiance [W/m2]"
+    annotation (Placement(transformation(extent={{-140,-80},{-100,-40}}),
+        iconTransformation(extent={{-140,-80},{-100,-40}})));
+
+  // Outputs
+  Modelica.Blocks.Interfaces.RealOutput pEl
+    "Total electrical power output [W/m2]"
+    annotation (Placement(transformation(extent={{100,40},{140,80}}),
+        iconTransformation(extent={{100,40},{140,80}})));
+  Modelica.Blocks.Interfaces.RealOutput temMod
+    "Average cell temperature [K]"
+    annotation (Placement(transformation(extent={{100,-20},{140,20}}),
+        iconTransformation(extent={{100,-20},{140,20}})));
+  Modelica.Blocks.Interfaces.RealOutput temMea
+    "Average fluid temperature [K]"
+    annotation (Placement(transformation(extent={{100,-80},{140,-40}}),
+        iconTransformation(extent={{100,-80},{140,-40}})));
+
+protected
+  Real temCell[nSeg];
+  Real temDiff[nSeg];
+  Real solarPowerInternal[nSeg];
+
+equation
+  for i in 1:nSeg loop
+    temCell[i] = Tm[i] + qth[i] / UAbsFluid;
+    temDiff[i] = temCell[i] - TpvtRef;
+    solarPowerInternal[i] = (A_c/nSeg) * (P_nominal/A) * (HGloTil/HGloHorNom) *
+                            (1 + gamma * temDiff[i]) * (1 - pLossFactor);
+  end for;
+
+  pEl = sum(solarPowerInternal);
+  temMod = sum(temCell)/nSeg;
+  temMea = sum(Tm)/nSeg;
+
+annotation (
+  defaultComponentName="eleGen",
+  Documentation(info="<html>
+<p>
+This component computes the electrical power output of a photovoltaic-thermal (PVT) collector using the PVWatts v5 methodology (Dobos, 2014), adapted for PVT systems. It is part of a validated, open-source Modelica implementation that relies solely on manufacturer datasheet parameters, as described in Meertens et al. (2025).
+</p>
+
+<p>
+The model calculates the electrical output for each segment <i>i ∈ {1, ..., n<sub>seg</sub>}</i> as:
+</p>
+
+<p align=\"center\" style=\"font-style:italic;\">
+P<sub>el,i</sub> = (A<sub>c</sub> / n<sub>seg</sub>) · (P<sub>nom</sub> / A) · (G<sub>tilt</sub> / G<sub>nom</sub>) · (1 + γ · ΔT<sub>i</sub>) · (1 - pLossFactor)
+</p>
+
+<p>
+where:
+<ul>
+  <li><i>ΔT<sub>i</sub></i> = T<sub>cell,i</sub> - T<sub>ref</sub>: temperature difference between PV cell and reference temperature</li>
+  <li><i>P<sub>nom</sub></i>: nominal PV power under STC [W]</li>
+  <li><i>A</i>: gross collector area [m²]</li>
+  <li><i>A<sub>c</sub></i>: effective collector area (equal to A if not otherwise specified)</li>
+  <li><i>G<sub>tilt</sub></i>: global irradiance on the tilted collector plane [W/m²]</li>
+  <li><i>G<sub>nom</sub></i>: nominal irradiance (typically 1000 W/m²)</li>
+  <li><i>γ</i>: temperature coefficient of power [%/K]</li>
+  <li><i>pLossFactor</i>: lumped system loss factor</li>
+</ul>
+</p>
+<p>
+The PV cell temperature is estimated from the fluid temperature and thermal power density using:
+</p>
+<p align=\"center\" style=\"font-style:italic;\">
+T<sub>cell,i</sub> = T<sub>m,i</sub> + q<sub>th,i</sub> / U<sub>AbsFluid</sub>
+</p>
+<p>
+  The internal heat transfer coefficient <i>UAbsFluid</i> is approximately calculated from datasheet parameters:
+</p>
+<div style=\"display:flex; align-items:center; justify-content:center;\">
+<div style=\"padding-right:8px;\"><i>UAbsFluid = </i></div>
+  <table style=\"border-collapse:collapse; text-align:center;\">
+    <tr>
+      <td style=\"padding:4px;\">
+        <em>(τ·α)<sub>eff</sub> – η<sub>0,el</sub></em> · (c<sub>1</sub> + c<sub>3</sub>·u + b<sub>1,el</sub>)
+      </td>
+    </tr>
+    <tr>
+      <td style=\"border-top:1px solid black; padding:4px;\">
+        <em>(τ·α)<sub>eff</sub> – η<sub>0,el</sub></em>
+        – (1 – <em>c<sub>6</sub>/η<sub>0,th</sub></em>·u) · η<sub>0,th</sub>
+      </td>
+    </tr>
+  </table>
+</div>
+<ul>
+  <li>
+    Here, <i>(τ·α)</i><sub>eff</sub> = 0.901 for unglazed PVT collectors as reported in Lämmle (2018), and = 0.84 for covered collectors.
+  </li>
+  <li>
+    The electrical temperature‑dependence term is <i>b</i><sub>1,el</sub> = |<i>β</i>| · G<sub>nom</sub>, where <i>β</i> is the temperature coefficient of power (in % K<sup>−1</sup>) and G<sub>nom</sub> = 1000 W m<sup>−2</sup>.
+  </li>
+  <li>
+    <i>u</i> is the in‑plane wind speed. In this approximation, <code>u = 0</code> is used to derive <i>UAbsFluid</i>—the internal heat transfer coefficient is only weakly dependent on external wind speed when the datasheet thermal parameters are accurate (Stegmann 2011).
+  </li>
+</ul>
+<h5>Electrical performance and losses</h5>
+<p>
+The electrical submodel includes an overall system loss factor <code>pLossFactor</code>. NREL’s PVWatts reports a total electrical power loss of 14%, resulting from the following mechanisms:
+</p>
+<table border=\"1\" cellpadding=\"4\">
+  <tr>
+    <th style=\"text-align:left;\">Electrical power loss mechanism</th>
+    <th style=\"text-align:center;\">Default value</th>
+  </tr>
+  <tr>
+    <td style=\"text-align:left;\">Soiling</td>
+    <td style=\"text-align:center;\">2 %</td>
+  </tr>
+  <tr>
+    <td style=\"text-align:left;\">Shading</td>
+    <td style=\"text-align:center;\">3 %</td>
+  </tr>
+  <tr>
+    <td style=\"text-align:left;\">Mismatch</td>
+    <td style=\"text-align:center;\">2 %</td>
+  </tr>
+  <tr>
+    <td style=\"text-align:left;\">Wiring</td>
+    <td style=\"text-align:center;\">2 %</td>
+  </tr>
+  <tr>
+    <td style=\"text-align:left;\">Connections</td>
+    <td style=\"text-align:center;\">0.5 %</td>
+  </tr>
+  <tr>
+    <td style=\"text-align:left;\">Light‑induced degradation</td>
+    <td style=\"text-align:center;\">1.5 %</td>
+  </tr>
+  <tr>
+    <td style=\"text-align:left;\">Nameplate rating</td>
+    <td style=\"text-align:center;\">1 %</td>
+  </tr>
+  <tr>
+    <td style=\"text-align:left;\">Availability</td>
+    <td style=\"text-align:center;\">3 %</td>
+  </tr>
+  <tr>
+    <th style=\"text-align:left;\">Total</th>
+    <th style=\"text-align:center;\">14 %</th>
+  </tr>
+</table>
+<p>
+  For well-maintained, unshaded modules, experimental validation (Meertens et al., 2025)
+found that using <code>pLossFactor = 9 %</code> gives excellent agreement with
+measured electrical output. For PVT collectors with high positive tolerance on the 
+electrical output, this system loss factor can even be reduced more. 
+Users may adjust <code>pLossFactor</code> to account for site-specific soiling or shading effects.
+</p>
+<h4>Implementation Notes</h4>
+<p>
+This model is designed for (unglazed) PVT collectors and supports discretization into multiple segments to capture temperature gradients along the flow path. It is compatible with the thermal 
+model based on ISO 9806:2013 and is suitable for dynamic simulations where irradiance and fluid temperatures vary over time.
+</p>
+
+<h4>References</h4>
+  <ul>
+    <li>
+      Dobos, A.P., <i>PVWatts Version 5 Manual</i>, NREL, 2014
+    </li>
+    <li>
+      Meertens, L., Jansen, J., Helsen, L. (2025). <i>Development and Experimental Validation of an Unglazed Photovoltaic-Thermal Collector Modelica Model that only needs Datasheet Parameters</i>, submitted to the 16th International Modelica & FMI Conference, Lucerne, Switzerland, Sep 8–10, 2025.
+    </li>
+    <li>
+      ISO 9806:2013, Solar energy — Solar thermal collectors — Test methods
+    </li>
+  </ul>
+</html>",
+revisions="<html>
+  <ul>
+   <li>
+      July 7, 2025, by Lone Meertens:<br/>
+      First implementation PVT model; tracked in 
+      <a href=\"https://github.com/open-ideas/IDEAS/issues/1436\">
+        IDEAS #1436
+      </a>.
+    </li>
+  </ul>
+</html>"));
+
+end ElectricalPVT;

IDEAS/Fluid/PvtCollectors/BaseClasses/Examples/ISO9806HeatLoss.mo

@@ -0,0 +1,122 @@
+within IDEAS.Fluid.PVTCollectors.BaseClasses.Examples;
+model ISO9806HeatLoss
+  "Example showing the use of ISO9806QuasiDynamicHeatLoss"
+  extends Modelica.Icons.Example;
+  parameter IDEAS.Fluid.PVTCollectors.Data.GenericQuasiDynamic per=
+      IDEAS.Fluid.PVTCollectors.Data.Uncovered.UI_Validation()
+    "Performance data" annotation (choicesAllMatching=true);
+  Modelica.Blocks.Sources.Sine T1(
+    amplitude=15,
+    f=0.1,
+    offset=273.15 + 10) "Temperature of the first segment"
+    annotation (Placement(transformation(extent={{-92,-22},{-72,-2}})));
+  Modelica.Blocks.Sources.Sine T2(
+    f=0.1,
+    amplitude=15,
+    offset=273.15 + 15) "Temperature of the second segment"
+    annotation (Placement(transformation(extent={{-68,-36},{-48,-16}})));
+  Modelica.Blocks.Sources.Sine T3(
+    f=0.1,
+    amplitude=15,
+    offset=273.15 + 20) "Temperature of the third segment"
+    annotation (Placement(transformation(extent={{-90,-52},{-70,-32}})));
+  ISO9806QuasiDynamicHeatLoss heaLosQuaDyn(
+    nSeg=3,
+    redeclare package Medium = IDEAS.Media.Water,
+    c1=per.c1,
+    c2=per.c2,
+    c3=per.c3,
+    c4=per.c4,
+    c6=per.c6,
+    A_c=per.A) annotation (Placement(transformation(extent={{18,-2},{38,18}})));
+
+  SolarCollectors.BaseClasses.EN12975HeatLoss heaLosSteSta(
+    A_c=per.A,
+    nSeg=3,
+    redeclare package Medium = IDEAS.Media.Water,
+    a1=per.c1,
+    a2=per.c2)
+    annotation (Placement(transformation(extent={{18,-68},{38,-48}})));
+  Modelica.Blocks.Sources.Sine TEnv(
+    f=0.01,
+    offset=273.15 + 10,
+    amplitude=15) "Temperature of the surrounding environment"
+    annotation (Placement(transformation(extent={{-80,24},{-60,44}})));
+  Modelica.Blocks.Sources.Sine winSpePla(
+    f=1/(24*3600),
+    phase=0,
+    offset=3,
+    amplitude=5) "wind speed in the collector plane"
+    annotation (Placement(transformation(extent={{60,58},{80,78}})));
+  Modelica.Blocks.Sources.RealExpression HHorIR(y=400) "long wave irradiance"
+    annotation (Placement(transformation(extent={{-1.5,58},{17.5,74}})));
+  Modelica.Blocks.Interfaces.RealOutput QLos_flow_QuaDyn[3]
+    "Limited heat loss rate at current conditions"
+    annotation (Placement(transformation(extent={{60,-2},{80,18}})));
+  Modelica.Blocks.Interfaces.RealOutput QLos_flow_SteSta[3]
+    "Limited heat loss rate at current conditions"
+    annotation (Placement(transformation(extent={{62,-68},{82,-48}})));
+  Modelica.Blocks.Sources.RealExpression HGloTil(y=800) "long wave irradiance"
+    annotation (Placement(transformation(extent={{26.5,58},{45.5,74}})));
+equation
+  connect(winSpePla.y, heaLosQuaDyn.winSpePla);
+  connect(HHorIR.y,  heaLosQuaDyn.HHorIR);
+  connect(HGloTil.y,  heaLosQuaDyn.HGloTil);
+  connect(T3.y, heaLosQuaDyn.TFlu[3]) annotation (Line(points={{-69,-42},{-44,-42},
+          {-44,2},{-20,2},{-20,2.66667},{16,2.66667}},
+                                      color={0,0,127}));
+  connect(T2.y, heaLosQuaDyn.TFlu[2]) annotation (Line(points={{-47,-26},{-44,-26},
+          {-44,2},{16,2}},      color={0,0,127}));
+  connect(TEnv.y, heaLosQuaDyn.TEnv) annotation (Line(points={{-59,34},{8,34},{8,
+          14},{16,14}}, color={0,0,127}));
+  connect(heaLosSteSta.TEnv, TEnv.y) annotation (Line(points={{16,-52},{8,-52},{
+          8,34},{-59,34}}, color={0,0,127}));
+  connect(T1.y, heaLosSteSta.TFlu[1]) annotation (Line(points={{-71,-12},{-68,
+          -12},{-68,2},{-44,2},{-44,-64.6667},{16,-64.6667}},
+                                                         color={0,0,127}));
+  connect(T2.y, heaLosSteSta.TFlu[2]) annotation (Line(points={{-47,-26},{-44,-26},
+          {-44,-64},{16,-64}}, color={0,0,127}));
+  connect(T3.y, heaLosSteSta.TFlu[3]) annotation (Line(points={{-69,-42},{-44,
+          -42},{-44,-63.3333},{16,-63.3333}},
+                                         color={0,0,127}));
+  connect(T1.y, heaLosQuaDyn.TFlu[1]) annotation (Line(points={{-71,-12},{-68,-12},
+          {-68,1.33333},{16,1.33333}}, color={0,0,127}));
+  connect(heaLosQuaDyn.QLos_flow, QLos_flow_QuaDyn)
+    annotation (Line(points={{39,8},{70,8}}, color={0,0,127}));
+  connect(heaLosSteSta.QLos_flow, QLos_flow_SteSta)
+    annotation (Line(points={{39,-58},{72,-58}}, color={0,0,127}));
+  annotation (
+   Documentation(info="<html>
+<p>
+This example demonstrates the implementation of
+<a href=\"modelica://IDEAS.Fluid.PVTCollectors.BaseClasses.ISO9806QuasiDynamicHeatLoss\">
+IDEAS.Fluid.PVTCollectors.BaseClasses.ISO9806QuasiDynamicHeatLoss</a>,
+which calculates the quasi-dynamic heat loss of a PVT or solar thermal collector
+according to the ISO 9806:2013 standard.
+</p>
+
+<p>
+In addition to showcasing the ISO 9806-based model, this example also compares its behavior
+to the steady-state heat loss model
+<a href=\"modelica://IDEAS.Fluid.SolarCollectors.BaseClasses.EN12975HeatLoss\">
+IDEAS.Fluid.SolarCollectors.BaseClasses.EN12975HeatLoss</a>,
+which is based on the now-superseded EN 12975 standard.
+</p>
+
+<p>
+This comparison highlights the differences between the steady-state and quasi-dynamic
+approaches, particularly in how they account for environmental factors such as wind speed
+and long-wave irradiance.
+</p>
+</html>",
+revisions="<html>
+<ul>
+<li>
+July 2, 2025, by Lone Meertens:<br/>
+First implementation of ISO 9806 quasi-dynamic heat loss example.<br/>
+This is for
+<a href=\"https://github.com/open-ideas/IDEAS/issues/1436\">IDEAS, #1436</a>.
+</li>
+</ul>
+</html>"), experiment(Tolerance=1e-6, StopTime=100));
+end ISO9806HeatLoss;

IDEAS/Fluid/PvtCollectors/BaseClasses/Examples/package.mo

@@ -0,0 +1,24 @@
+within IDEAS.Fluid.PVTCollectors.BaseClasses;
+package Examples
+  "Collection of models that illustrate model use and test models"
+extends Modelica.Icons.ExamplesPackage;
+
+annotation (preferredView="info", Documentation(info="<html>
+<p>
+This package contains examples for the use of models that can be found in
+<a href=\"modelica://IDEAS.Fluid.PVTCollectors.BaseClasses\">
+IDEAS.Fluid.PvtCollectors.BaseClasses.</a>
+</p>
+</html>",
+revisions="<html>
+  <ul>
+   <li>
+      July 7, 2025, by Lone Meertens:<br/>
+      First implementation PVT model; tracked in 
+      <a href=\"https://github.com/open-ideas/IDEAS/issues/1436\">
+        IDEAS #1436
+      </a>.
+    </li>
+  </ul>
+</html>"));
+end Examples;

IDEAS/Fluid/PvtCollectors/BaseClasses/Examples/package.order

@@ -0,0 +1 @@
+ISO9806HeatLoss