Issue1436 add pvt model

.gitattributes

@@ -1,17 +1,15 @@
 # Set default behaviour, in case users don't have core.autocrlf set.
 * text=auto
-
 # Explicitly declare text files we want to always be normalized and converted 
 # to native line endings on checkout.
 *.mo text
 *.mos text
 *.mop text
 *.py text
 *.txt text
-
 # Declare files that will always have CRLF line endings on checkout.
 #*.sln text eol=crlf
-
 # Denote all files that are truly binary and should not be modified.
 *.png binary
 *.jpg binary
+IDEAS/Resources/Data/Fluid/PVTCollectors/Validation/PVT_UN/PVT_UN_measurements.txt filter=lfs diff=lfs merge=lfs -text

.github/workflows/github-actions.yml

@@ -78,6 +78,9 @@ jobs:
         run: make test-dymola PACKAGE=\"IDEAS.Fluid.MixingVolumes\" INTERACTIVE=false
       - name: Test IDEAS.Fluid.Movers
         run: make test-dymola PACKAGE=\"IDEAS.Fluid.Movers\" INTERACTIVE=false
+      - name: Test IDEAS.Fluid.PVTCollectors
+        run: make test-dymola PACKAGE=\"IDEAS.Fluid.PVTCollectors.BaseClasses.Examples\" INTERACTIVE=false
+            && make test-dymola PACKAGE=\"IDEAS.Fluid.PVTCollectors.Examples\" INTERACTIVE=false 
       - name: Test IDEAS.Fluid.Sensors
         run: make test-dymola PACKAGE=\"IDEAS.Fluid.Sensors\" INTERACTIVE=false
       - name: Test IDEAS.Fluid.SolarCollectors

IDEAS/Fluid/PVTCollectors/BaseClasses/ElectricalPVT.mo

@@ -0,0 +1,210 @@
+within IDEAS.Fluid.PVTCollectors.BaseClasses;
+model ElectricalPVT
+  "Calculate the electrical power output of a PVT using the PVWatts v5 approach"
+  extends Modelica.Blocks.Icons.Block;
+  extends IDEAS.Fluid.SolarCollectors.BaseClasses.PartialParameters;
+
+  // Parameters
+  parameter Modelica.Units.SI.Irradiance HGloHorNom = 1000 "global horizontal irradiances";
+  parameter Modelica.Units.SI.Efficiency eleLosFac = 0.09 "PV loss factor";
+  parameter Modelica.Units.SI.Temperature TpvtRef = 298.15 "Reference cell temperature";
+  parameter Real gamma "Temperature coefficient [1/K]";
+  parameter Modelica.Units.SI.Power P_nominal "Nominal PV power";
+  parameter Modelica.Units.SI.Area A "PV area";
+  parameter Modelica.Units.SI.Efficiency eta0 "Zero-loss efficiency";
+  parameter Modelica.Units.SI.DimensionlessRatio tauAlpEff "Effective transmittance–absorptance product";
+  parameter Modelica.Units.SI.CoefficientOfHeatTransfer c1 "First-order heat loss coefficient";
+  parameter Modelica.Units.SI.Efficiency etaEl "Electrical efficiency";
+
+  parameter Modelica.Units.SI.CoefficientOfHeatTransfer UAbsFluid =
+    ((tauAlpEff - etaEl) * (c1 + abs(gamma)*HGloHorNom)) / ((tauAlpEff - etaEl) - eta0)
+    "Heat transfer coefficient between the fluid and the PV cells, calculated from datasheet parameters";
+
+  // Inputs
+  Modelica.Blocks.Interfaces.RealInput Tflu[nSeg]
+    "Fluid temperatures per segment [K]"
+    annotation (Placement(transformation(extent={{-140,40},{-100,80}}),
+        iconTransformation(extent={{-140,40},{-100,80}})));
+  Modelica.Blocks.Interfaces.RealInput Qth[nSeg]
+    "Thermal power density per segment [W/m2]"
+    annotation (Placement(transformation(extent={{-140,-20},{-100,20}}),
+        iconTransformation(extent={{-140,-20},{-100,20}})));
+  Modelica.Blocks.Interfaces.RealInput HGloTil
+    "Global tilted irradiance [W/m2]"
+    annotation (Placement(transformation(extent={{-140,-80},{-100,-40}}),
+        iconTransformation(extent={{-140,-80},{-100,-40}})));
+
+  // Outputs (user-facing)
+  Modelica.Blocks.Interfaces.RealOutput Pel
+    "Total electrical power output [W]"
+    annotation (Placement(transformation(extent={{100,40},{140,80}}),
+        iconTransformation(extent={{100,40},{140,80}})));
+  Modelica.Blocks.Interfaces.RealOutput TavgCel
+    "Average PV module temperature [K]"
+    annotation (Placement(transformation(extent={{100,-20},{140,20}}),
+        iconTransformation(extent={{100,-20},{140,20}})));
+  Modelica.Blocks.Interfaces.RealOutput TavgFlu
+    "Average fluid temperature [K]"
+    annotation (Placement(transformation(extent={{100,-80},{140,-40}}),
+        iconTransformation(extent={{100,-80},{140,-40}})));
+
+protected
+  // internal variables (not exposed as connectors)
+  Modelica.Units.SI.Temperature temMod "Average cell/module temperature ";
+  Modelica.Units.SI.Temperature temMea "Average fluid temperature";
+  Modelica.Units.SI.Temperature TCel[nSeg];
+  Modelica.Units.SI.Temperature TDif[nSeg];
+  Modelica.Units.SI.Power Pel_int[nSeg];
+
+equation
+  for i in 1:nSeg loop
+    TCel[i] = Tflu[i] +Qth[i] / UAbsFluid;
+    TDif[i] = TCel[i] - TpvtRef;
+    Pel_int[i] = (A_c/nSeg) * (P_nominal/A) * (HGloTil/HGloHorNom) *
+                            (1 + gamma * TDif[i]) * (1 - eleLosFac);
+  end for;
+
+  Pel = sum(Pel_int);
+  temMod = sum(TCel) / nSeg;
+  temMea = sum(Tflu) / nSeg;
+  TavgCel = temMod;
+  TavgFlu = temMea;
+
+annotation (
+  defaultComponentName="eleGen",
+  Documentation(info="<html>
+<p>
+This component computes the electrical power output of a photovoltaic-thermal (PVT) collector using the PVWatts v5 methodology (Dobos, 2014), adapted for PVT systems.
+It is part of a validated, open-source Modelica implementation that relies solely on manufacturer datasheet parameters, as described in Meertens et al. (2025).
+</p>
+<p>
+The model calculates the electrical output for each segment <i>i ∈ {1, ..., n<sub>seg</sub>}</i> as:
+</p>
+<p align=\"center\" style=\"font-style:italic;\">
+P<sub>el,i</sub> = (A<sub>c</sub> / n<sub>seg</sub>) &#183 (P<sub>nom</sub> / A) 
+&#183 (G<sub>tilt</sub> / G<sub>nom</sub>) &#183 (1 + &gamma; &#183 &Delta;T<sub>i</sub>) &#183 (1 - eleLosFac)
+</p>
+<p>
+where:
+<ul>
+<li>
+<i>&Delta;T<sub>i</sub> = T<sub>cell,i</sub> - T<sub>ref</sub></i>: temperature difference between PV cell and reference temperature
+</li>
+<li>
+<i>P<sub>nom</sub></i>: nominal PV power under STC [W]
+</li>
+<li>
+<i>A</i>: gross collector area [m²]
+</li>
+<li>
+<i>A<sub>c</sub></i>: effective collector area (equal to A if not otherwise specified)
+</li>
+<li>
+<i>G<sub>tilt</sub></i>: global irradiance on the tilted collector plane [W/m²]
+</li>
+<li>
+<i>G<sub>nom</sub></i>: nominal irradiance (typically 1000 W/m²)
+</li>
+<li>
+<i>&gamma;</i>: temperature coefficient of power [%/K]
+</li>
+<li>
+<i>eleLosFac</i>: lumped system loss factor
+</li>
+</ul>
+</p>
+<p>
+The PV cell temperature is estimated from the fluid temperature and thermal power density using:
+</p>
+<p align=\"center\" style=\"font-style:italic;\">
+T<sub>cell,i</sub> = T<sub>m,i</sub> + q<sub>th,i</sub> / U<sub>AbsFluid</sub>
+</p>
+<p>
+The internal heat transfer coefficient <i>UAbsFluid</i> is approximately calculated from datasheet parameters. 
+For the mathematical description and visualisation, see <a href='modelica://IDEAS.Fluid.PVTCollectors.UsersGuide'>IDEAS.Fluid.PVTCollectors.UsersGuide</a>.
+</p>
+
+<h5>Electrical performance and losses</h5>
+<p>
+The electrical submodel includes an overall system loss factor <code>eleLosFac</code>. 
+PVWatts reports a total electrical power loss of 14%, resulting from the following mechanisms:
+</p>
+<table border=\"1\" cellpadding=\"4\">
+<tr>
+<th style=\"text-align:left;\">Electrical power loss mechanism</th>
+<th style=\"text-align:center;\">Default value</th>
+</tr>
+<tr>
+<td style=\"text-align:left;\">Soiling</td>
+<td style=\"text-align:center;\">2 %</td>
+</tr>
+<tr>
+<td style=\"text-align:left;\">Shading</td>
+<td style=\"text-align:center;\">3 %</td>
+</tr>
+<tr>
+<td style=\"text-align:left;\">Mismatch</td>
+<td style=\"text-align:center;\">2 %</td>
+</tr>
+<tr>
+<td style=\"text-align:left;\">Wiring</td>
+<td style=\"text-align:center;\">2 %</td>
+</tr>
+<tr>
+<td style=\"text-align:left;\">Connections</td>
+<td style=\"text-align:center;\">0.5 %</td>
+</tr>
+<tr>
+<td style=\"text-align:left;\">Light‑induced degradation</td>
+<td style=\"text-align:center;\">1.5 %</td>
+</tr>
+<tr>
+<td style=\"text-align:left;\">Nameplate rating</td>
+<td style=\"text-align:center;\">1 %</td>
+</tr>
+<tr>
+<td style=\"text-align:left;\">Availability</td>
+<td style=\"text-align:center;\">3 %</td>
+</tr>
+<tr>
+<th style=\"text-align:left;\">Total</th>
+<th style=\"text-align:center;\">14 %</th>
+</tr>
+</table>
+<p>
+For well-maintained, unshaded modules, experimental validation (Meertens et al., 2025)
+found that using <code>eleLosFac = 9%</code> gives excellent agreement with
+measured electrical output. For PVT collectors with a high positive tolerance on the 
+electrical output, this system loss factor can even be lower. 
+Users may adjust <code>eleLosFac</code> to account for site-specific soiling or shading effects.
+</p>
+
+<h4>Implementation Notes</h4>
+<p>
+This model is designed for (unglazed) PVT collectors and supports discretization into multiple segments to capture temperature gradients along the flow path. 
+It is compatible with the thermal model based on ISO 9806:2013 and is suitable for dynamic simulations where irradiance and fluid temperatures vary over time.
+</p>
+
+<h4>References</h4>
+<ul>
+<li>
+Dobos, A. P. (2014). <i><a href='https://docs.nrel.gov/docs/fy14osti/62641.pdf'>PVWatts Version 5 Manual</a></i>. NREL/TP-6A20-62641
+</li>
+<li>
+Meertens, L., Jansen, J., Helsen, L. (2025).
+<i>Development and Experimental Validation of an Unglazed Photovoltaic-Thermal Collector Modelica Model that only needs Datasheet Parameters</i>,
+submitted to the 16th International Modelica & FMI Conference, Lucerne, Switzerland, Sep 8–10, 2025.
+</li>
+</ul>
+</html>",
+revisions="<html>
+<ul>
+<li>
+July 7, 2025, by Lone Meertens:<br/>
+First implementation PVT model. 
+This is for <a href=\"https://github.com/open-ideas/IDEAS/issues/1436\">#1436</a>.
+</li>
+</ul>
+</html>"));
+
+end ElectricalPVT;

IDEAS/Fluid/PVTCollectors/BaseClasses/Examples/ISO9806HeatLoss.mo

@@ -0,0 +1,129 @@
+within IDEAS.Fluid.PVTCollectors.BaseClasses.Examples;
+model ISO9806HeatLoss
+  "Example showing the use of ISO9806QuasiDynamicHeatLoss"
+  extends Modelica.Icons.Example;
+  replaceable package Medium = IDEAS.Media.Water "Medium in the system";
+
+  parameter IDEAS.Fluid.PVTCollectors.Data.GenericQuasiDynamic per=
+      IDEAS.Fluid.PVTCollectors.Data.Uncovered.UI_Validation()
+    "Performance data" annotation (choicesAllMatching=true);
+  Modelica.Blocks.Sources.Sine T1(
+    amplitude=15,
+    f=0.1,
+    offset=273.15 + 10) "Temperature of the first segment"
+    annotation (Placement(transformation(extent={{-92,-22},{-72,-2}})));
+  Modelica.Blocks.Sources.Sine T2(
+    f=0.1,
+    amplitude=15,
+    offset=273.15 + 15) "Temperature of the second segment"
+    annotation (Placement(transformation(extent={{-68,-36},{-48,-16}})));
+  Modelica.Blocks.Sources.Sine T3(
+    f=0.1,
+    amplitude=15,
+    offset=273.15 + 20) "Temperature of the third segment"
+    annotation (Placement(transformation(extent={{-90,-52},{-70,-32}})));
+  ISO9806QuasiDynamicHeatLoss heaLosQuaDyn(
+    nSeg=3,
+    redeclare package Medium = Medium,
+    c1=per.c1,
+    c2=per.c2,
+    c3=per.c3,
+    c4=per.c4,
+    c6=per.c6,
+    A_c=per.A) annotation (Placement(transformation(extent={{18,-2},{38,18}})));
+
+  IDEAS.Fluid.SolarCollectors.BaseClasses.EN12975HeatLoss heaLosSteSta(
+    A_c=per.A,
+    nSeg=3,
+    redeclare package Medium = Medium,
+    a1=per.c1,
+    a2=per.c2)
+    annotation (Placement(transformation(extent={{18,-68},{38,-48}})));
+  Modelica.Blocks.Sources.Sine TEnv(
+    f=0.01,
+    offset=273.15 + 10,
+    amplitude=15) "Temperature of the surrounding environment"
+    annotation (Placement(transformation(extent={{-80,24},{-60,44}})));
+  Modelica.Blocks.Sources.Sine winSpePla(
+    f=1/(24*3600),
+    phase=0,
+    offset=3,
+    amplitude=5) "wind speed in the collector plane"
+    annotation (Placement(transformation(extent={{60,58},{80,78}})));
+  Modelica.Blocks.Sources.RealExpression HHorIR(y=400) "long wave irradiance"
+    annotation (Placement(transformation(extent={{-1.5,58},{17.5,74}})));
+  Modelica.Blocks.Interfaces.RealOutput QLos_flow_QuaDyn[3]
+    "Heat loss rate at current conditions"
+    annotation (Placement(transformation(extent={{60,-2},{80,18}})));
+  Modelica.Blocks.Interfaces.RealOutput QLos_flow_SteSta[3]
+    "Heat loss rate at current conditions"
+    annotation (Placement(transformation(extent={{62,-68},{82,-48}})));
+  Modelica.Blocks.Sources.RealExpression HGloTil(y=800) "Global irradiance on the tilted surface"
+    annotation (Placement(transformation(extent={{26.5,58},{45.5,74}})));
+equation
+  connect(winSpePla.y, heaLosQuaDyn.winSpePla);
+  connect(HHorIR.y,  heaLosQuaDyn.HHorIR);
+  connect(HGloTil.y,  heaLosQuaDyn.HGloTil);
+  connect(T3.y, heaLosQuaDyn.TFlu[3]) annotation (Line(points={{-69,-42},{-44,-42},
+          {-44,2},{-20,2},{-20,2.66667},{16,2.66667}},
+                                      color={0,0,127}));
+  connect(T2.y, heaLosQuaDyn.TFlu[2]) annotation (Line(points={{-47,-26},{-44,-26},
+          {-44,2},{16,2}},      color={0,0,127}));
+  connect(TEnv.y, heaLosQuaDyn.TEnv) annotation (Line(points={{-59,34},{8,34},{8,
+          14},{16,14}}, color={0,0,127}));
+  connect(heaLosSteSta.TEnv, TEnv.y) annotation (Line(points={{16,-52},{8,-52},{
+          8,34},{-59,34}}, color={0,0,127}));
+  connect(T1.y, heaLosSteSta.TFlu[1]) annotation (Line(points={{-71,-12},{-68,
+          -12},{-68,2},{-44,2},{-44,-64.6667},{16,-64.6667}},
+                                                         color={0,0,127}));
+  connect(T2.y, heaLosSteSta.TFlu[2]) annotation (Line(points={{-47,-26},{-44,-26},
+          {-44,-64},{16,-64}}, color={0,0,127}));
+  connect(T3.y, heaLosSteSta.TFlu[3]) annotation (Line(points={{-69,-42},{-44,
+          -42},{-44,-63.3333},{16,-63.3333}},
+                                         color={0,0,127}));
+  connect(T1.y, heaLosQuaDyn.TFlu[1]) annotation (Line(points={{-71,-12},{-68,-12},
+          {-68,1.33333},{16,1.33333}}, color={0,0,127}));
+  connect(heaLosQuaDyn.QLos_flow, QLos_flow_QuaDyn)
+    annotation (Line(points={{39,8},{70,8}}, color={0,0,127}));
+  connect(heaLosSteSta.QLos_flow, QLos_flow_SteSta)
+    annotation (Line(points={{39,-58},{72,-58}}, color={0,0,127}));
+  annotation (
+   Documentation(info="<html>
+<p>
+This example demonstrates the implementation of
+<a href=\"modelica://IDEAS.Fluid.PVTCollectors.BaseClasses.ISO9806QuasiDynamicHeatLoss\">
+IDEAS.Fluid.PVTCollectors.BaseClasses.ISO9806QuasiDynamicHeatLoss</a>,
+which calculates the quasi-dynamic heat loss of a PVT or solar thermal collector
+according to the ISO 9806:2013 standard.
+</p>
+<p>
+In addition to showcasing the ISO 9806-based model, this example also compares its behavior
+to the steady-state heat loss model
+<a href=\"modelica://IDEAS.Fluid.SolarCollectors.BaseClasses.EN12975HeatLoss\">
+IDEAS.Fluid.SolarCollectors.BaseClasses.EN12975HeatLoss</a>,
+which is based on the now-superseded EN 12975 standard.
+</p>
+<p>
+This comparison highlights the differences between the steady-state and quasi-dynamic
+approaches, particularly in how they account for environmental factors such as wind speed
+and long-wave irradiance.
+</p>
+</html>",
+revisions="<html>
+<ul>
+<li>
+July 2, 2025, by Lone Meertens:<br/>
+First implementation of ISO 9806 quasi-dynamic heat loss example.
+This is for <a href=\"https://github.com/open-ideas/IDEAS/issues/1436\">1436</a>.
+</li>
+</ul>
+</html>"), 
+__Dymola_Commands(file="modelica://IDEAS/Resources/Scripts/Dymola/Fluid/PVTCollectors/BaseClasses/Examples/ISO9806HeatLoss.mos"
+        "Simulate and plot"),
+ experiment(
+      StartTime=0,
+      StopTime=86400,
+      Interval=60,
+      Tolerance=1e-06,
+      __Dymola_Algorithm="dassl"));
+end ISO9806HeatLoss;

IDEAS/Fluid/PVTCollectors/BaseClasses/Examples/package.mo

@@ -0,0 +1,13 @@
+within IDEAS.Fluid.PVTCollectors.BaseClasses;
+package Examples
+  "Collection of models that illustrate model use and test models"
+extends Modelica.Icons.ExamplesPackage;
+
+annotation (preferredView="info", Documentation(info="<html>
+<p>
+This package contains examples for the use of models that can be found in
+<a href=\"modelica://IDEAS.Fluid.PVTCollectors.BaseClasses\">
+IDEAS.Fluid.PvtCollectors.BaseClasses.</a>
+</p>
+</html>"));
+end Examples;

IDEAS/Fluid/PVTCollectors/BaseClasses/Examples/package.order

@@ -0,0 +1 @@
+ISO9806HeatLoss